Ako rýchlo pripojiť posledný upravený súbor v priečinku Windows k e-mailu v programe Outlook

Občas budete možno chcieť rýchlo nájsť a pripojiť posledný upravený súbor v konkrétnom priečinku Windows k e-mailu programu Outlook. V takom prípade môžete použiť metódu uvedenú v tomto článku.

Niektorí používatelia chcú, aby Outlook rýchlo zistil a pridal k e-mailu naposledy upravený súbor v priečinku systému Windows, napríklad naposledy vytvorený, zmenený alebo uložený súbor. Outlook však takúto priamu a natívnu funkciu neponúka. Preto v nasledujúcom texte uvedieme časť kódu VBA, ktorá to dokáže jednoducho realizovať.

Pripojte posledný upravený súbor v priečinku Windows k e-mailu

1. Hneď na začiatku by ste mali spustiť aplikáciu Outlook.
2. Potom, ako sa dostanete do hlavného okna programu Outlook, môžete stlačiť klávesové skratky „Alt + F11“.
3. Ďalej úspešne vstúpite do okna editora Outlook VBA.
4. Následne by ste mali nájsť a otvoriť modul, ktorý sa práve nepoužíva.
5. A potom skopírujte a prilepte nasledujúci kód VBA do tohto okna modulu.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Potom môžete opustiť súčasné okno editora VBA a pokračovať v pridávaní nového makra na panel nástrojov Rýchly prístup alebo na pásku v okne Správa.
7. Neskôr budete musieť zmeniť úroveň zabezpečenia makra programu Outlook na nízku.
8. Nakoniec to môžete vyskúšať.

• Najskôr vytvorte a vytvorte nový e-mail programu Outlook ako obvykle.
• Potom stlačte tlačidlo makra na paneli s nástrojmi Rýchly prístup, ako je to na obrázku nižšie:
• Ďalej budete musieť zvoliť zdrojový priečinok Windows a stlačiť „OK“.
• Ak sa vo vybranom priečinku systému Windows taký súbor nachádza, zobrazí sa výzva, ako napríklad na nasledujúcom obrázku:
• Po stlačení „Áno“ sa tento súbor pripojí naraz.

Riešte problémy s Outlookom čo najskôr

Kedykoľvek narazíte na akýkoľvek problém s programom Outlook, odporúča sa ich vyriešiť čo najskôr. V tejto situácii si radšej pripravte robustný Oprava programu Outlook nástroj vopred, ako napr DataNumen Outlook Repair. Je schopný opraviť chyby PST a efektívne zachrániť vaše údaje z Outlooku.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane poškodený mdf a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S