Ako rýchlo extrahovať všetkých príjemcov z viacerých súborov správ Outlook (.msg)

Niektorí používatelia by chceli rýchlo extrahovať všetkých príjemcov z viacerých súborov správ programu Outlook uložených z e-mailov programu Outlook. Teraz, táto strost sa na to zameria a bude zdieľať rýchly prístup.

Ak chcete príjemcov extrahovať z jedného súboru správ programu Outlook, otvorte ich dvojitým kliknutím a potom ich skopírujte do otvoreného okna správy. Ak však potrebujete narábať s dávkou súborov správ Outlook, manuálna metóda nie je dostatočne efektívna. Môžete teda hľadať oveľa efektívnejší spôsob. Tu vám taký predstavíme. Čítajte ďalej a získate ďalšie podrobnosti.

Extrahujte všetkých príjemcov z viacerých súborov správ Outlook (.msg)

1. Pre akotart, získať prístup k editoru Outlook VBA podľa “Ako spustiť kód VBA v programe Outlook".
2. Ďalej skopírujte a vložte nasledujúci kód VBA do prázdneho modulu.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Potom posuňte kurzor na prvý podprogram.
4. Následne kliknite na tlačidlo „Spustiť“ alebo stlačte kláves „F5“.
5. Potom v rozbaľovacom dialógovom okne vyberte priečinok Windows, ktorý obsahuje zdrojové súbory správ Outlook (.msg).
6. Po výbere kliknite na „OK“, aby sa makro dalo ďalej spustiť.
7. Po dokončení makra sa zobrazí správa so zoznamom všetkých e-mailových adries extrahovaných príjemcov, ako je znázornené na nasledujúcej snímke obrazovky.

Chráňte svoje údaje programu Outlook pred nebezpečenstvom

Dáta programu Outlook sú nepochybne náchylné na poškodenie. Preto je dosť náročná úloha chrániť údaje programu Outlook. Vyžaduje si to vytrvalosť pri pravidelnom zálohovaní údajov Outlooku. Ak je to možné, je tiež obozretné a odporúča sa pripraviť si skúsený a profesionálny výhľad Oprava PST nástroj, ako DataNumen Outlook Repair, aby ste mohli v prípade poškodenia aplikácie Outlook získať okamžitú a včasnú záchranu.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane zotaviť sa Sql Server a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S