Ako získať oznámenie, ak nedostanete odpoveď na konkrétny e-mail v očakávanom čase

Tento článok vás naučí rýchly trik pomocou jazyka VBA, ktorý vám umožní, aby vás program Outlook automaticky vyzval, či chcete poslať e-mail s oznámením, keď ste v konkrétnom čase nedostali odpoveď na konkrétny e-mail.

V prípade zásadne dôležitých e-mailov sa občas určite budete tešiť na ich odpovede. Inými slovami, musíte dúfať, že príjemca vám môže odpovedať čo najskôr. V opačnom prípade, ak ste ešte nedostali odpoveď v očakávanom čase, príjemcovi znova pošlete e-mail s následným oznámením. Preto v reakcii na túto požiadavku predstavíme metódu, ktorá pomocou VBA umožní aplikácii Outlook automatické varovanie a výzvu v takom prípade. Čítajte ďalej a získate zložité kroky a kódy.

Ak nedostanete odpoveď na konkrétny e-mail v očakávanom čase, dostanete oznámenie

1. Hneď na úvod starváš Outlook.
2. Potom musíte pre konkrétny e-mail nastaviť konkrétny čas pripomenutia.

• Najskôr kliknite pravým tlačidlom myši na konkrétny e-mail.
• Potom zvoľte „Sledovať“> „Pridať pripomenutie“.
• V dialógovom okne môžete nastaviť čas pripomienky rovnako ako konkrétny čas, v ktorom chcete dostať jeho odpoveď.

3. Potom stlačte klávesovú skratku „Alt + F11“, aby ste sa dostali do editora Outlook VBA.
4. Ďalej v novom okne otvorte projekt „ThisOutlookSession“ a skopírujte doň nasledujúce kódy.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

5. Následne tento kód podpíšte.
6. Neskôr zmeňte nastavenie makra Outlooku, aby ste povolili digitálne podpísané makrá.
7. Prípadne restart Outlook aktivovať nové makro. Odteraz bude Outlook fungovať nasledovne:

• Ak ste dostali odpoveď na konkrétny e-mail skôr, ako sa objaví jeho pripomienka, Outlook automaticky vymaže príznak a deaktivuje pripomienku.
• Ak ste nedostali odpoveď, keď sa spustí jej pripomienka, Outlook sa vás opýta, či chcete poslať e-mail s následným oznámením. Ak vyberiete možnosť „Áno“, e-mail sa odošle. Ak vyberiete možnosť „Nie“, výzva zmizne naraz.

Vyriešte nepríjemné problémy s programom Outlook

Pretože Outlook je náchylný na chyby, aby sa zabránilo Výhľadová korupcia, radšej by ste sa nemali spoliehať iba na nástroj na doručenú poštu Scanpst.exe. Mali by ste pripraviť ďalší účinný a renomovaný nástroj na opravu, ako je napr DataNumen Outlook Repair, ktoré môžu odstraňovať nepríjemné problémy, ktoré program Scanpst.exe nedokáže vyriešiť.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane korupcia sql a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S