Ako efektívne pridávať poznámky k e-mailom z Outlooku prostredníctvom VBA a UserForm

Niekedy môžete dúfať, že k svojim e-mailom v Outlooku upravíte alebo pridáte poznámky. Tento článok vám predstaví efektívny spôsob dosiahnutia tejto funkcie.

Z „4 jednoduché spôsoby vloženia poznámky do správ programu Outlook„, Môžete sa naučiť vkladať poznámky do e-mailov pomocou natívnych funkcií Outlooku, ako je použitie vlastných príznakov, písanie poznámky do predmetu alebo tela alebo pripojenie existujúcich položiek poznámok k tomuto e-mailu. Všetky z nich sú však iba riešením problému. Tu vás naučíme oveľa efektívnejšiu metódu. Prostredníctvom neho budete môcť pridávať poznámky do e-mailov a upravovať alebo mazať existujúce poznámky podľa ľubovôle.

Pridajte poznámky k e-mailom Outlook

1. Najskôr otvorte editor VBA stlačením kombinácie klávesov „Alt + F11“ v Outlooku.
2. Potom kliknite na „Vložiť“> „UserForm“.
3. Ďalej v novom UserForm vytvorte textové pole ako na obrázku nižšie.
4. Potom zmeňte „Názov“ textového poľa na „txtNotes“, ako je napríklad snímka obrazovky.
5. Potom vo formulári vytvorte dva príkazové tlačidlá.
6. Potom vyberte „CommandButton 1“. Zmeňte jeho „Názov“ na „btnOK“ a zmeňte jeho „Titul“ na „OK“.
7. Potom zmeňte „Názov“ „CommandVutton 2“ na „btnCancel“ a „Názov“ na „Zrušiť“.
8. Ďalej vyberte celý UserForm a upravte jeho „Name“ na „frmAddNote“ a „Caption“ na „Enter your note“.
9. Následne kliknite pravým tlačidlom myši na „fromAddNote“ a zvoľte „Zobraziť kód“.
10. Na novej obrazovke skopírujte do nej nasledujúci kód.

Private Sub btnOK_Click()
    Dim strNote As String
    Dim objMail As Outlook.MailItem
    Dim objNote As Outlook.NoteItem
 
    strNote = txtNotes.Text
 
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    Set objNote = Application.CreateItem(olNoteItem)
 
    objNote.Body = strNote
    objNote.Save
    objMail.Attachments.Add objNote
    objMail.Save
    objNote.Delete
    Unload Me
End Sub

Private Sub btnCancel_Click()
    Unload Me
End Sub

11. Neskôr vložte kód VBA nižšie do nepoužívaného modulu.

Sub AddNote()
    frmAddNote.Show
End Sub

12. Nakoniec prejdite na „Súbor“> „Možnosti“> „Prispôsobiť pásku“ a pridajte toto makro na pásku.
13. Teraz to môžete vyskúšať. Vyberte e-mail a kliknite na nové tlačidlo „Pridať poznámku“ na páse s nástrojmi.
14. V rozbaľovacom dialógovom okne môžete zadať poznámku a kliknúť na „OK“.
15. K vybranému e-mailu bude okamžite pridaná nová poznámka.

Upraviť alebo odstrániť existujúce poznámky pre e-maily programu Outlook

Niekedy môžete upraviť alebo vymazať všetky existujúce poznámky v e-maile. Môžete postupovať podľa nasledujúcich pokynov.

1. Najskôr vytvorte ďalší používateľský formulár a pomenujte ho ako „frmEditNote“ a upravte jeho popis na „Upraviť poznámku“.
2. Potom do formulára vložte nové textové pole a zmeňte jeho „Názov“ na „txtNotes“.
3. Ďalej pridajte dve príkazové tlačidlá - „OK“ a „Zrušiť“.
4. Potom kliknite pravým tlačidlom myši na „frmEditNote“ a vyberte „Zobraziť kód“.
5. Na novú kódovú stránku „frmEditNote“ vložte nasledujúci kód.

Private Sub UserForm_Initialize()
    Dim objAttachNote As Outlook.Attachment
    Dim objTempNote As Outlook.NoteItem

    Set objAttachNote = ActiveExplorer.AttachmentSelection.Item(1)
    Set objMail = objAttachNote.Parent
 
    If Right(objAttachNote.FileName, 3) = "msg" Then
       strTempFolder = Environ("Temp")
       strFilePath = strTempFolder & "\" & objAttachNote.FileName
       objAttachNote.SaveAsFile strFilePath
    End If
 
    Set objTempNote = Session.OpenSharedItem(strFilePath)
    txtNotes.Text = objTempNote.Body

    objTempNote.Close olDiscard
End Sub

Private Sub btnOK_Click()
    Dim strNote As String
    Dim objMail As Outlook.MailItem
    Dim objAttachNote As Outlook.Attachment
    Dim objNewNote As Outlook.NoteItem
 
    strNote = txtNotes.Text
 
    Set objNewNote = Application.CreateItem(olNoteItem)
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    Set objAttachNote = ActiveExplorer.AttachmentSelection.Item(1)
    objAttachNote.Delete

    objNewNote.Body = strNote
    objNewNote.Save
    objMail.Attachments.Add objNewNote
    objMail.Save
    objNewNote.Delete
    Unload Me
End Sub

Private Sub btnCancel_Click()
    Unload Me
End Sub

6. Potom otvorte modul a skopírujte do neho kód VBA.

Sub EditNote()
    frmEditNote.Show
End Sub

Sub DeleteNotes()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim objMail As Outlook.MailItem
 
    Set objSelectedAttachments = Application.ActiveExplorer.AttachmentSelection
 
    For Each objAttachment In objSelectedAttachments
        If Right(objAttachment.FileName, 3) = "msg" Then
           objAttachment.Delete
        End If
    Next
 
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    objMail.Save
End Sub

7. Nakoniec môžete na pás karet pridať makrá „EditNote“ a „DeleteNotes“.
8. Nakoniec po kliknutí na tlačidlo „OK“ a návrate do hlavného okna môžete skúsiť poznámku upraviť.

• Vyberte poznámku a kliknite na tlačidlo „Upraviť poznámku“.
• Potom sa zobrazí nové dialógové okno, v ktorom môžete upraviť vybratú poznámku.
• Po dokončení úprav kliknite na tlačidlo „OK“. Poznámka bude aktualizovaná.

9. Môžete sa tiež pokúsiť odstrániť všetky poznámky.

• Vyberte poznámku, ktorú chcete odstrániť.
• Kliknite na tlačidlo „Odstrániť poznámky“ na páse s nástrojmi.
• Táto poznámka bude odstránená naraz.

Zabráňte strate dát v Outlooku

Hľadáte mocné riešenie na blokovanie straty údajov v Outlooku? Úprimne povedané, pokiaľ pravidelne zálohujete dáta z Outlooku, môžete sa ľahko vyhnúť ich strate. Napríklad aj keď sa PST poškodí, stále môžete ľahko obnoviť PST dáta zo zálohovaného súboru PST ako vánok.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane obnoviť sql a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S