Ako je možné v programe Outlook odstrániť dávky zo zastaraných položiek kalendára

Ak chcete odstrániť prílohy zo zastaraných stretnutí a schôdzí v programe Outlook, môžete si prečítať tento článok. Tu vám predstavíme, ako to zrealizovať naraz.

Ak chcete zmenšiť veľkosť svojho súboru Outlook, je veľmi vhodné vyčistiť staré položky. To sa dá dosiahnuť pomocou zabudovanej funkcie „AutoArchive“, ktorá dokáže staré položky v pravidelných intervaloch automaticky mazať. Niektorí používatelia si však len želajú odstrániť prílohy v starých položkách bez toho, aby to ovplyvnilo samotné položky. V nasledujúcich častiach vás naučíme hromadne odstraňovať prílohy zo starých položiek kalendára.

Hromadne odstráňte prílohy zo zastaraných položiek kalendára

1. Na začiatok otvorte editor Outlook VBA pomocou klávesovej skratky „Alt + F11“.
2. Potom v okne „Microsoft Visual Basic for Applications“ skopírujte kód VBA do modulu.

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. Potom kliknite na makro „BatchDeleteAttachmentsOfOldCalendarItems“.
4. Nakoniec spustite toto makro stlačením klávesu „F5“.
5. Po dokončení makra môžete skontrolovať všetky svoje kalendáre programu Outlook.
6. Program Outlook musí odstrániť všetky prílohy položiek kalendára, ktoré sú staršie ako 2 mesiace.

Vyrovnajte si poškodené súbory programu Outlook

Stretli ste sa niekedy s korupciou Outlooku? Ako to obvykle zlikvidujete? Najčastejšie by ste najskôr vyskúšali nástroj na opravu doručenej pošty - Scanpst. Ale v prípade vážneho poškodenia PST vám zabudovaný nástroj nemôže pomôcť. Preto sa navrhuje ponechať v blízkosti skúsenejší a pozoruhodný nástroj tretej strany, ako napr DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane oprava sql a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S