Ako automaticky nastaviť iný čas pripomenutia pre stretnutia programu Outlook v rôznych farebných kategóriách

Ak klasifikujete schôdze programu Outlook podľa farebných kategórií a chcete nastaviť iný čas pripomienky pre schôdzky v rôznych farebných kategóriách, môžete si prečítať tento článok. Tu vás naučíme realizovať to pomocou aplikácie Outlook VBA.

Napríklad rozdeľujete stretnutia do dvoch skupín. Jedna je vo farebnej kategórii „Mimo pracoviska“, pretože miesto konania stretnutia je príliš ďaleko, a druhá je vo farebnej kategórii „Na pracovisku“, pretože miesto konania je priamo tu. Teraz chcete, aby Outlook automaticky nastavil čas pripomenutia stretnutia „mimo pracoviska“ na 1 hodinu pred začiatkom a stretnutia „na pracovisku“ na 15 minút pred začiatkom. Vzhľadom na túto požiadavku si ďalej ukážeme rýchly postup.

Automaticky nastaviť inú pripomienku pre stretnutia v rôznych farebných kategóriách

1. Najskôr spustite aplikáciu Outlook.
2. Potom stlačte klávesy „Alt + F11“, aby ste vstúpili do okna editora VBA.
3. Ďalej v nasledujúcom okne skopírujte a prilepte nižšie uvedený kód VBA do projektu „ThisOutlookSession“.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Neskôr musíte kliknúť na podprogram „Application_Startup“ a stlačiť kláves „F5“, aby ste spustili toto makro.
5. Odvtedy vždy, keď sa do predvoleného kalendára pridá nová schôdzka alebo zmeníte existujúcu schôdzku, Outlook automaticky skontroluje kategórie schôdzky a automaticky nastaví iný čas pripomenutia.

Eliminujte chyby programu Outlook

V programe Outlook sa môžu z času na čas vyskytnúť rôzne problémy. Preto je mimoriadne dôležité, aby sa používatelia naučili, ako sa s problémami v programe Outlook vysporiadať. Na začiatok by ste mali pravidelne zálohovať dáta v programe Outlook. Okrem toho, ak je to dostupné, odporúča sa mať silný Oprava Outlook nástroj v blízkosti, ako napr DataNumen Outlook Repair. Môže skenovať váš súbor PST, zistiť problémy s Outlookom a potom ich ľahko vyriešiť.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane zotavenie sql a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S