Ako automaticky zaznamenávať celkový počet prichádzajúcich e-mailov každý deň do súboru programu Excel

Tento článok vás naučí, ako nechať program Outlook automaticky spočítať, koľko e-mailov ste dostali každý deň, a zapísať ich do súboru Excel.

Od mnohých používateľov sa vyžaduje, aby spočítali celkový počet e-mailov prijatých každý deň. Pre pohodlnejšiu kontrolu v budúcnosti je navyše veľa ľudí zvyknutých zaznamenávať celkový počet do súboru Excel. V takom prípade sa samozrejme môžete rozhodnúť počítať a zaznamenávať každý deň ručne. Je to však trochu nepríjemné. A možno zabudnete na to, že to niekedy robíte. Preto musíte mať praktickú metódu, vďaka ktorej môže Outlook automaticky vykonať túto akciu. V reakcii na túto požiadavku vás naučíme, ako používať jazyk VBA na jeho realizáciu v nasledujúcich častiach.

Automaticky každý deň zaznamenávať celkový počet prichádzajúcich e-mailov do súboru programu Excel

1. Hneď na začiatku spustite aplikáciu Outlook.
2. Potom stlačte klávesové skratky „Alt + F11“ v hlavnom okne programu Outlook.
3. Ďalej v kontextovom okne editora VBA otvorte projekt „ThisOutlookSession“.
4. Následne skopírujte a prilepte nasledujúce kódy VBA do tohto projektu.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Ďalej tento kód podpíšte a zmeňte nastavenie makier programu Outlook tak, aby umožňovalo podpísané makrá.
6. Potom musíte každý deň vytvárať opakujúce sa úlohy.

• Najskôr kliknite na tlačidlo „Nová úloha“ na table Úlohy.
• V rozbaľovacom okne Nová úloha kliknite na tlačidlo „Opakovanie“.
• Potom v nasledujúcom dialógovom okne zvoľte „Denne“, „Každý 1 deň (dni)“ a „Žiadny dátum ukončenia“ a nakoniec stlačte „OK“.
• Neskôr zmeňte predmet úlohy a pripomenutie podľa svojich potrieb.
• Nakoniec kliknite na tlačidlo „Uložiť a zavrieť“.

7. Odteraz bude program Outlook pri každom upozornení na pripomenutie tejto úlohy automaticky počítať e-maily prijaté včera a potom ich číslo zaznamená do súboru Excel, napríklad na nasledujúcom obrázku:

Únik z trvalej straty dát PST

Nikto nie je ochotný akceptovať trvalú stratu údajov PST. Súbor PST programu Outlook je však náchylný na poškodenie. Preto by ste mali urobiť dostatočné preventívne opatrenia, napríklad vytvoriť konzistentné a aktuálne zálohovanie údajov PST a zachovať ich výkonnosť Obnova PST nástroj v okolí, ako DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane oprava sql a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S