Ako automaticky exportovať informácie o prichádzajúcich e-mailoch do súboru programu Excel pomocou programu Outlook VBA

Mnoho používateľov dúfa, že Outlook dokáže automaticky exportovať primárne informácie prichádzajúcich e-mailov do súboru Excel. Tento článok sa bude zaoberať touto požiadavkou a predstaví rýchlu metódu cez Outlook VBA.

Niekedy z určitých dôvodov, ako sú štatistiky pošty, možno budete často musieť exportovať e-maily do súboru programu Excel. Vo všeobecnosti môžete pre existujúce prijaté e-maily jednoducho použiť funkciu „Importovať a exportovať“ a exportovať ich do Excelu naraz. Možno si však dokonca želáte, aby Outlook mohol automaticky exportovať prichádzajúce e-maily do Excelu hneď, ako dorazia do vašej poštovej schránky. Bez akýchkoľvek pochybností takáto natívna funkcia v programe Outlook neexistuje. Preto musíte použiť iné prístupy, ako napríklad doplnok tretej strany alebo Outlook VBA. Tu vás naučíme, ako ho zautomatizovať pomocou programu Outlook VBA. Čítajte ďalej a získajte kroky a podľa kódov.

Automatický export informácií o prichádzajúcich e-mailoch do súboru programu Excel

1. V prvom rade by ste mali vytvoriť súbor Excel.

• Otvorte nový súbor programu Excel.
• Potom by ste mali zadať „Nie“. v bunke A1, „Meno odosielateľa“ v bunke B1, „E-mailová adresa odosielateľa“ v bunke C1 a „Predmet e-mailu“ v bunke D1 a „Čas prijatia“ v bunke E1, ako na nasledujúcom obrázku.
• Nakoniec ho uložte do požadovaného názvu a požadovaného priečinka.

2. Potom by ste mali spustiť program Outlook.
3. Potom stlačte klávesy „Alt + F11“, čím sa dostanete do editora VBA.
4. Ďalej vo vyskakovacom okne by ste mali dvakrát kliknúť na „ThisOutlookSession“ na ľavej strane.
5. Následne v okne projektu “ThisOutlookSession” musíte skopírovať a vložiť doň nasledujúce kódy VBA.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. Neskôr by ste mali tento kód podpísať.
7. Následne restart Outlook na aktiváciu nového projektu VBA.
8. Nakoniec sa odteraz všetky prichádzajúce e-maily automaticky exportujú do prednastaveného súboru Excel, len čo sa dostanú do priečinka Doručená pošta. Excel súbor bude vyzerať ako nasledujúci obrázok:

Zabráňte bolestivému poškodeniu údajov PST

Outlook si vďaka svojim rôznym funkciám vyslúžil veľa chvály. To však neznamená, že je to spoľahlivé. Stále môže byť kedykoľvek kompromitovaná. Ak napríklad často nesprávne zatvárate program Outlook, je veľmi pravdepodobné, že vaše údaje PST budú ohrozené. V tomto prípade, ak by ste chceli opraviť PST údajov, musíte sa obrátiť na skúsený nástroj, ako napr DataNumen Outlook Repair.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane vymáhať mdf a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S