2 spôsoby, ako tlačiť zoznamy úloh programu Outlook s rôznymi kategóriami na rôznych stránkach

Ak ste svojim úlohám v Outlooku priradili rôzne farebné kategórie a chcete teraz vytlačiť zoznam úloh s rôznymi kategóriami na rôznych stránkach, môžete si prečítať tento článok. Tu vám poskytneme 2 spôsoby, ako to získať.

Možno ste na svoje úlohy klasifikovali a dobre spravovali svoje úlohy. Ak si teraz chcete vytlačiť zoznamy svojich úloh s rôznymi kategóriami na rôznych stránkach, čítajte ďalej. V nasledujúcom texte vám predstavíme 2 spôsoby, ako to získať.

Metóda 1: Ručná tlač zoznamov úloh jeden po druhom

1. Najskôr v Outlooku otvorte tablu „Úlohy“.
2. Potom otvorte priečinok Úloha.
3. Potom stlačte kombináciu klávesov „Ctrl + E“ a aktivujte pásku „Hľadať“.
4. Potom na karte „Vyhľadávanie“ kliknite na tlačidlo „Kategorizovať“.
5. Z rozbaľovacieho zoznamu vyberte farebnú kategóriu.
6. Potom v zozname zostanú iba úlohy s vybranou kategóriou.
7. Teraz prejdite na „Súbor“> „Tlačiť“ a vytlačte si tento zoznam úloh.
8. Rovnakým spôsobom si následne rovnakým spôsobom po jednom ručne vytlačte zoznamy úloh s ostatnými farebnými kategóriami.

Metóda 2: Hromadná tlač zoznamov úloh pomocou VBA

1. Hneď na začiatku spustite editor VBA v súlade s „Ako spustiť kód VBA v programe Outlook".
2. Potom pridajte odkaz na „Knižnicu objektov MS Excel“ podľa pokynov „Ako pridať odkaz na knižnicu objektov vo VBA".
3. Ďalej skopírujte nasledujúci kód VBA do modulu.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Potom stlačte tlačidlo „F5“, aby ste toto makro okamžite spustili.
5. Po dokončení makra sa zoznam úloh s rôznymi kategóriami vytlačí na rôznych stránkach, ako je to znázornené na nasledujúcej snímke obrazovky.

Získajte späť cenné údaje z kompromitovaného súboru PST

Ak ste predmetom neprístupného súboru PST, vašim ďalším krokom je nepochybne Oprava PST. V takom prípade môžete najskôr vyskúšať nástroj na opravu doručenej pošty. Ak zlyhá, môžete vyskúšať ďalší externý nástroj, ako napr DataNumen Outlook Repair. Je schopný obnoviť dáta PST v rýchlom čase.

Úvod autora:

Shirley Zhang je expertkou na obnovu dát v DataNumen, Inc., ktorá je svetovým lídrom v oblasti technológií obnovy dát, vrátane vymáhať mdf a výhľadové softvérové ​​produkty na opravu. Pre viac informácií navštívte www.datanumen. S