Как автоматически установить Outlook Online или Offline в зависимости от вашего рабочего времени

Некоторые пользователи хотели бы, чтобы Outlook автоматически переключался между онлайновым и автономным статусом в зависимости от их рабочего времени. Итак, в этой статье мы поделимся с вами быстрым методом.

На самом деле настроить Outlook онлайн или офлайн очень просто. Чтобы перевести Outlook в автономный режим, вы можете просто перейти на вкладку «Отправить/получить» и нажать кнопку «Работать автономно». А чтобы вернуться в онлайн-статус, просто снова нажмите эту кнопку. Однако некоторые пользователи надеются, что Outlook может автоматически переключаться в автономный режим в нерабочее время и возвращаться в онлайн в рабочее время. Хотя Outlook не предоставляет такой функции, вы все равно можете использовать следующий код VBA для ее реализации.

Автоматическая установка Outlook в сети или в автономном режиме в зависимости от вашего рабочего времени

1. В самом начале сtarт ваше приложение Outlook.
2. Затем, получив доступ к Outlook, вы должны открыть папку «Задачи».
3. Затем вы должны создать ежедневно повторяющийся элемент задачи.

• Нажмите кнопку «Новая задача» на ленте.
• Затем введите «Не в сети» в строке темы задачи.
• Затем нажмите кнопку «Повторение» на вкладке «Задача».
• Во всплывающем диалоговом окне выберите шаблон повторения «Ежедневно», включите «Без даты окончания» и нажмите «ОК».
• Затем вы должны включить напоминание в «5:00».
• Наконец, нажмите кнопку «Сохранить и закрыть».

4. Впоследствии вам нужно создать еще одну ежедневную повторяющуюся задачу под названием «В сети» и включить напоминание в «8:00», как показано на рисунке ниже:
5. После этого в главном окне Outlook нажмите клавиши «Alt + F11».
6. Далее вы получите доступ к редактору Outlook VBA, в котором вам нужно найти и открыть проект «ThisOutlookSession».
7. Позже скопируйте следующий код VBA в этот проект.

Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

8. В конце концов, вы можетеtart Outlook, чтобы активировать этот макрос.
9. Отныне ваш Outlook будет в сети в рабочее время и автоматически переключится в автономный режим в нерабочее время.

Ваше последнее средство в случае сбоев Outlook

Хотя Outlook может похвастаться множеством функций, Outlook по-прежнему не может избежать ошибок и повреждений. Но не паникуйте. Пока вы принимаете достаточные меры предосторожности, вы по-прежнему можете эффективно защищать свои данные Outlook. Например, вам следует регулярно создавать резервные копии файлов PST, так как резервные копии позволят вам вернуться поврежденный файл PST данные. Кроме того, наличие мощного инструмента для ремонта, такого как DataNumen Outlook Repair, тоже дело необходимости.

Об авторе:

Ширли Чжан — эксперт по восстановлению данных в DataNumen, Inc., которая является мировым лидером в области технологий восстановления данных, включая починить мдф и программные продукты для ремонта Outlook. Для получения дополнительной информации посетите www.datanumen.com