Cum se dezarhivează .Zip Atașamente Direct în Outlook prin VBA

Când primiți un atașament în „.zip„”, dacă doriți să le dezarhivați, în general, ar trebui să le salvați și să le dezarhivați pe unitatea locală. Dar mulți speră să le dezarhiveze direct în Outlook. Acest articol vă va învăța cum să o obțineți prin VBA.

Trebuie să fi primit vreodată anexele care se află în „.zip” extensie de fișier. Pentru a accesa fișierele interne într-unul singur zip fișier, trebuie mai întâi să îl dezarhivați. În acest caz, ca de obicei, trebuie mai întâi să salvați fișierul zip fișierul pe unitatea locală, apoi faceți clic dreapta pe el și selectați „Extrageți tot” din meniul contextual. În realitate, mulți utilizatori preferă să dezarhiveze fișierul direct în Outlook. Cu toate acestea, Outlook nu oferă o astfel de funcție nativă. Din fericire, puteți urma pașii de mai jos pentru a utiliza VBA și a realiza acest lucru foarte ușor.

Dezarhivați fișierul .Zip Atașamente direct în Outlook

1. În primul rând, lansați aplicația Outlook.
2. Apoi apăsați comanda rapidă a tastei „Alt + F11” în fereastra Outlook pentru a accesa editorul VBA.
3. Apoi, în fereastra „Microsoft Visual Basic for Applications”, deschideți un modul care nu este utilizat.
4. Ulterior, copiați și lipiți următoarele coduri VBA în acest modul.

Public Sub UnzipFileInOutlook()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objShell As Object
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim strFileName As String
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
    Set objAttachments = objMail.attachments
 
    'Save & Unzip the zip file in local drive
    Set objShell = CreateObject("Shell.Application")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "yyyy-mm-dd-hh-mm-ss")
    MkDir (strTempFolder)
 
    For Each objAttachment In objAttachments
        If Right(objAttachment.FileName, 3) = "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.FileName
           objAttachment.SaveAsFile (strFilePath)
           objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strFilePath)).Items
        End If
    Next
 
    'Reattach the files extracted from the zip file
    strFileName = Dir(strTempFolder & "\")
 
    While Len(strFileName) > 0
          objMail.attachments.Add (strTempFolder & "\" & strFileName)
          strFileName = Dir
          objMail.Save
    Wend
 
    'Delete the attachments in “.zip” file extension
    Set objAttachments = objMail.attachments
    For Each objAttachment In objAttachments
        If Right(objAttachment.FileName, 3) = "zip" Then
           objAttachment.Delete
           objMail.Save
        End If
    Next
 
    'Delete the temp folder and files
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. După aceea, puteți adăuga noul proiect VBA la bara de instrumente Acces rapid a ferestrei de mesaje, ca de obicei.
6. În sfârșit, puteți încerca.

• Mai întâi, deschideți un mesaj cu zip fișier în propria fereastră.
• Apoi faceți clic pe „Acțiuni” > „Editați mesajul”.
• Apoi faceți clic pe butonul macro nou din Bara de instrumente Acces rapid.
• Deodată, cel zip Fișierul va fi dezarhivat, ca în următoarea captură de ecran:

Scăpați de problemele PST enervante

Deși fișierul PST în noul format Unicode acceptă dimensiunea fișierului de 20 GB, este totuși înțelept să păstrați fișierul cât mai mic posibil. Se datorează faptului că un fișier PST mare este mult mai predispus la corupție. Odată ce fișierul dvs. PST este compromis, va trebui să faceți eforturi recuperați PST date. În acest scenariu, nu aveți de ales decât să recurgeți la un instrument bine dovedit și de renume, cum ar fi DataNumen Outlook Repair.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv reparație sql și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com