Cum să găsești rapid paragrafe cu o singură propoziție în documentul tău Word

În această postare, dorim să vă arătăm modalitatea rapidă de a găsi toate paragrafele dintr-o singură propoziție în documentul Word prin intermediul VBA.

Din când în când, unele documente pot avea cerințe foarte specifice pentru formatarea și structurile lor. De exemplu, este posibil să nu vi se permită să aveți paragrafe cu o singură propoziție. Aceste paragrafe nu sunt greu de recunoscut, dar este nevoie de timp, mai ales că este un document lung.

Astăzi, vă vom oferi modalitatea rapidă de a specifica toate paragrafele cu o singură propoziție din documentul dvs.

Găsiți toate paragrafele cu o singură propoziție într-un singur document

1. În primul rând, Word numără un punct ca o propoziție. Deci, dacă există cuvinte precum „Domnul.” sau „Doamna”, Word îl consideră ca pe o propoziție. Pentru a exclude o astfel de distragere a atenției, trebuie să înlocuiți „dl.” cu „domnul”. Și când găsești paragraful dintr-o singură propoziție, le poți schimba înapoi. Pentru a înlocui cuvintele, puteți consulta acest link: Cum să găsiți și să înlocuiți mai multe elemente în documentul dvs. Word
2. În al doilea rând, apăsați „Alt+ F11” pentru a declanșa editorul VBA.
3. Apoi faceți clic pe proiect „Normal”.
4. Faceți clic pe fila „Inserare” din bara de meniu și alegeți „Modul” din meniul său vertical.
5. Apoi faceți dublu clic pe modul pentru a-l deschide.
6. Lipiți următoarele coduri pe modul:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Nu în ultimul rând, faceți clic pe butonul „Run” sau apăsați „F5”.

Veți primi o astfel de casetă de mesaj, care vă spune că treaba este gata.

Găsiți toate paragrafele cu o singură propoziție în mai multe documente

1. Pentru început, trebuie să puneți toate documentele țintă într-un dosar.
2. Apoi instalați și rulați macrocomanda următoare:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. În fereastra „Răsfoiți” deschisă, alegeți folderul în care păstrați documentele și faceți clic pe „OK”.

Macro-ul va evidenția apoi toate paragrafele cu o singură propoziție și va lăsa documentele deschise. Dacă un document nu conține un paragraf cu o singură propoziție, acesta va fi închis. În plus, există o casetă de mesaj, care indică numărul de paragrafe cu o propoziție din fiecare document.

Rezolvați incidentul de pierdere a datelor

Erorile utilizatorului și întreruperile bruște de curent pot duce la moartea Word. În timp ce un Cuvânt prăbușit nu poate afecta numai munca de zi cu zi, dar poate duce și la doc deteriorareAceasta nu este nicidecum cea mai iritantă parte a unui dezastru legat de date. Este mai bine să obțineți un utilitar de reparare pentru a recupera datele imediat.

Introducerea autorului:

Vera Chen este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv recupera excel și pdf repararea produselor software. Pentru mai multe informații vizitați www.datanumen.com