Cum să exportați rapid timpul total petrecut la întâlnirile Outlook în fiecare categorie de culoare

Dacă doriți să creați un raport despre timpul total petrecut cu programările din fiecare categorie de culoare, puteți utiliza metoda introdusă în acest articol. Vă poate ajuta să realizați acest lucru în timp util, fără a fi nevoie să numărați manual.

Mulți utilizatori sunt obișnuiți să înregistreze majoritatea activităților lor în calendarul Outlook. De asemenea, pentru a le gestiona și diferenția mai ușor, atribuie categorii fiecăreia dintre ele. În acest caz, unii utilizatori ar dori să genereze un raport care să arate timpul total petrecut pe elementele din calendar din fiecare categorie de culoare. Fără îndoială, este dificil să numărați și să introduceți manual datele. Prin urmare, aici vom împărtăși o modalitate prin care puteți realiza această sarcină printr-un simplu clic.

Exportați timpul total petrecut cu programările din fiecare categorie de culoare

1. În primul rând, lansați aplicația Outlook.
2. Apoi, după ce ați intrat în fereastra Outlook, puteți apăsa pe butoanele tastei „Alt + F11”.
3. Ulterior, veți avea acces la fereastra „Microsoft Visual Basic pentru aplicații”.
4. Apoi, va trebui să activați „Biblioteca de obiecte Microsoft Excel”. Puteți face clic pe „Instrumente” > „Referințe” pentru a face acest lucru.
5. Apoi, ar trebui să găsiți și să deschideți un modul care nu este în uz.
6. După aceea, trebuie să copiați următorul cod VBA în acest modul.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. În cele din urmă, puteți declanșa această macrocomandă, indiferent făcând clic pe pictograma „Run” din bara de instrumente sau apăsând butonul tastei „F5”.
8. Apoi, vi se va solicita să selectați un anumit calendar.
9. După ce selectați și apăsați „OK”, macrocomanda va continua să ruleze. După ce se termină, va apărea un nou fișier Excel care se va afișa în fundal.
10. Îl poți accesa. Va arăta ca următoarea captură de ecran:

Fiți atenți la potențialele amenințări din jurul Outlook

Utilizatorii Outlook ar trebui să aibă în vedere toate riscurile potențiale, inclusiv atașamentele de e-mail necunoscute, linkurile încorporate și erorile umane. În caz contrar, Outlook poate fi corupt în orice moment. De asemenea, realizarea obișnuită de copii de siguranță a datelor Outlook și păstrarea unui instrument specializat de reparare sunt chestiuni de necesitate. DataNumen Outlook Repair este unul dintre cele mai recomandate instrumente de reparare. Poate repara Outlook probleme într-o clipă.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv mdf deteriorat și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com