Cum să exportați rapid un folder Outlook cu toate subfolderele și elementele într-un folder Windows

Uneori, este posibil să doriți să exportați în serie un folder Outlook cu toate subfolderele și elementele într-un folder Windows. Acest articol vă va învăța o astfel de metodă care aplică Outlook VBA.

Când doriți să exportați un folder Outlook pe unitatea locală cu toate elementele din aceeași structură de foldere, dacă selectați să salvați și să exportați manual, vă va lua mult timp. Astfel, de ce nu apelezi la alte mijloace, precum orice instrumente de export sau coduri VBA? Aici vă vom dezvălui o astfel de bucată de cod VBA. Îți va permite să o atingi ca o briză.

Exportați toate subfolderele și elementele dintr-un folder Outlook într-un folder Windows

1. Chiar de la început, porniți programul Outlook.
2. Apoi, în fereastra principală Outlook, apăsați comenzile rapide „Alt + F11”.
3. Ulterior, va apărea fereastra „Microsoft Visual Basic for Applications”.
4. Apoi, trebuie să deschideți un modul gol și să copiați următoarele coduri VBA în el.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. După aceea, trebuie să vă asigurați că Outlook permite macrocomenzi în setările macro.
6. În cele din urmă, puteți încerca.

• În primul rând, înapoi la noua fereastră macro.
• Apoi faceți clic în subrutina „ExportFolderWithAllItems”.
• Apoi apăsați butonul F5 pentru a rula această macrocomandă.
• După aceea, trebuie să selectați un anumit folder.
• În cele din urmă, când primiți un mesaj care spune „Terminat”, puteți accesa folderul local predefinit. Veți găsi că toate elementele au fost salvate în aceeași structură de foldere.

Preveniți pierderea datelor de la blocările Outlook

Poate că ați întâlnit vreodată multe blocări ale Outlook. De cele mai multe ori, după o repornire, Outlook va putea funcționa normal. Cu toate acestea, există și cazurile în care fișierul PST se poate corupe. În acel moment, veți încerca să recuperați datele PST, cum ar fi apelând la un instrument experimentat, cum ar fi DataNumen Outlook Repair. Este capabil să remediați Outlook erori și extrageți date din fișierul PST compromis fără a transpira.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv SQL Server repara și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com