Cum să exportați rapid informațiile despre dimensiunea tuturor dosarelor dintr-un fișier PST într-un fișier Excel

Dacă doriți să verificați informațiile despre dimensiunea fiecărui folder dintr-un fișier PST, puteți utiliza metoda expusă în acest articol. Acesta va exporta rapid informațiile despre dimensiunea tuturor dosarelor dintr-un fișier PST într-un fișier Excel.

Când fișierul dvs. PST este prea mare, vă recomandăm să verificați dimensiunea fiecărui folder. Vă va ajuta să vă dați seama cu ușurință care sunt cele mai mari și să faceți o arhivare adecvată în funcție de dimensiune. În general, pentru a verifica dimensiunea folderului, puteți pur și simplu să faceți clic dreapta pe un folder și apoi să alegeți „Proprietăți”. În noua casetă de dialog pop-up, puteți face clic pe butonul „Dimensiunea folderului”. Cu toate acestea, dacă ați creat multe foldere, verificarea manuală a informațiilor despre dimensiune, una câte una, este considerabil deranjantă. Deci, dacă doriți să obțineți în serie informațiile despre dimensiunea tuturor folderelor dintr-un fișier PST, puteți utiliza următorul cod VBA. Acesta va exporta toate numele folderelor și informațiile despre dimensiune într-un fișier Excel dintr-o singură mișcare.

Exportați informațiile despre dimensiunea tuturor dosarelor dintr-un fișier PST într-un fișier Excel

1. Pentru început, lansați aplicația Outlook.
2. Apoi comutați la fila „Dezvoltator” și faceți clic pe butonul „Visual Basic” sau apăsați tastele „Alt + F11” pentru a accesa editorul VBA.
3. Apoi, în fereastra „Microsoft Visual Basic for Applications”, deschideți un modul care nu este utilizat.
4. Ulterior, copiați și lipiți următoarele coduri VBA în acest modul.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. După aceea, ar trebui să setați nivelul de securitate al macrocomenzii Outlook la scăzut.
6. În cele din urmă, puteți încerca.

• Apăsați butonul tasta F5 în fereastra macro curentă.
• Apoi vi se va solicita să selectați un fișier PST, cum ar fi următoarea imagine:
• După selectarea unui fișier sursă, Outlook va începe să exporte informațiile despre dimensiune în Excel.
• După terminarea macrocomenzii, primiți un mesaj precum captura de ecran de mai jos.
• În cele din urmă, veți putea găsi fișierul Excel în folderul local predefinit. Fișierul Excel va arăta astfel:

Faceți față erorilor PST frecvente

Deoarece Outlook este predispus la erori, este posibil să fi suferit vreodată multe probleme în Outlook. Pentru a face față mai bine și mai flexibil problemelor PST frustrante, este recomandabil să păstrați un utilitar de remediere cu experiență și reputație în apropiere, cum ar fi DataNumen Outlook Repair. Este capabil să reparați PST probleme ca o briză.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv SQL Server recuperare și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com