Cum să copiați rapid structura folderului dintr-un fișier PST Outlook în altul prin VBA

Dacă doriți să copiați structura folderului dintr-un fișier PST Outlook în altul, puteți utiliza metoda introdusă în acest articol, care vă va învăța cum să utilizați VBA pentru a-l obține dintr-o singură mișcare.

Poate că, pentru a vă gestiona mai bine e-mailurile, ați creat mai multe foldere personalizate în fișierul principal Outlook. Astfel, atunci când creați un nou fișier PST Outlook, este posibil să doriți să aplicați aceeași structură de foldere. De fapt, în articolul meu anterior – „2 pași pentru a păstra ierarhia curentă a folderelor într-un fișier Outlook nou”, puteți învăța o metodă tradițională, care utilizează caracteristica „Arhivare” pentru a o realiza. Cu toate acestea, de fapt, este încă puțin plictisitor. În comparație cu acesta, utilizarea codurilor VBA pentru a-l obține va fi mult mai rapidă. Prin urmare, în cele ce urmează, vă vom spune pașii și codurile elaborate.

Copiați structura folderului dintr-un fișier PST Outlook în altul

1. Chiar de la început, porniți programul Outlook.
2. Apoi, în fereastra Outlook, apăsați butoanele tastei „Alt + F11”.
3. Apoi veți intra în fereastra editorului Outlook VBA.
4. Ulterior, copiați și lipiți următoarele coduri VBA într-un modul nou.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. După aceea, schimbați nivelul de securitate macro la scăzut.
6. Mai târziu, înapoi la fereastra editorului VBA și apăsați butonul „F5” pentru a rula macro-ul.
7. În cele din urmă, după ce macro-ul termină de funcționare, veți primi un mesaj care vă va solicita „Terminat!”.
8. În acest moment, puteți accesa panoul de navigare prin e-mail. Veți vedea un nou fișier de date Outlook care se află în aceeași structură de foldere ca și fișierul PST sursă, ca în imaginea de mai jos:

Faceți față problemelor deprimante PST

Deoarece Outlook PST este predispus la erori, mulți dintre voi trebuie să fi întâlnit vreodată diverse probleme în Outlook. În fața lor, puteți utiliza mai întâi instrumentul de reparare a căsuței de intrare Outlook pentru a încerca. Dacă nu reușește, puteți aplica apoi un instrument terț mai puternic, cum ar fi DataNumen Outlook Repair, care poate remediați Outlook Erori PST ca o briză.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv SQL Server stabili și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com