Cum să deschideți în lot toate hyperlinkurile cu un anumit domeniu în e-mailul dvs. Outlook

Când vizualizați un e-mail Outlook care conține o mulțime de hyperlinkuri în corp, uneori, este posibil să doriți doar să deschideți rapid hyperlinkurile cu un anumit domeniu. Aici vom împărtăși o metodă de a deschide astfel de hyperlinkuri în bloc.

În fața mai multor hyperlinkuri într-un singur e-mail, puteți spera să verificați unele dintre ele, în loc de toate. De exemplu, ați dori doar să deschideți în loturi hyperlinkurile cu un anumit domeniu. În general, trebuie să faceți clic unul câte unul pentru a le deschide. Este foarte supărător. Prin urmare, în cele ce urmează, vă vom învăța o modalitate mai convenabilă.

Deschideți în lot toate hyperlinkurile cu un anumit domeniu în e-mail

1. Pentru noitart, accesați editorul Outlook VBA conform „Cum să rulați codul VBA în Outlook".
2. Ulterior, în fereastra „Microsoft Visual Basic for Applications”, activați referința la „MS Word Object Lib”rary” cu referire la „Cum să adăugați un obiect Library Referință în VBA".
3. Apoi, copiați următorul cod VBA într-un modul sau proiect neutilizat.

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. Apoi, adăugați această macrocomandă în Bara de instrumente Acces rapid sau în panglică.
5. În cele din urmă, faceți următorii pași pentru a încerca.

• În primul rând, selectați sau deschideți un e-mail Outlook.
• Apoi, faceți clic pe butonul macro.
• Imediat, hyperlinkurile cu domeniul predefinit în e-mail vor fi deschise în lot în Internet Explorer, așa cum se arată în imaginea următoare:

Scăpați de corupția iritante din Outlook

Deși Outlook este susceptibil la erori și corupție, de fapt, atâta timp cât ești atent la toate riscurile, poți scăpa de ele cu ușurință. De exemplu, trebuie să faceți copii de siguranță ale datelor pentru Outlook în mod regulat. În plus, ar trebui să fiți atenți la e-mailurile suspecte care pot conține viruși. Nu în ultimul rând, ar fi bine să pregătești un Repararea Outlook utilitate, cum ar fi DataNumen Outlook Repair. Este capabil să vă ajute în cazul corupției Outlook.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv corupt SQL Server și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com