Cum să salvați în lot mai multe e-mailuri nefinalizate ca șabloane Outlook

Poate ați creat mai multe e-mailuri nefinalizate și sperați să le reutilizați multe ori. Dacă da, de ce nu le salvați în lot ca șabloane Outlook? Acest articol vă va învăța să realizați acest lucru dintr-o singură mișcare prin VBA.

În mod implicit, Outlook permite utilizatorilor doar să salveze un singur e-mail ca șablon simultan. Cu alte cuvinte, nu puteți salva mai multe schițe de e-mail ca șabloane în bloc. După cum puteți vedea, când selectați mai multe e-mailuri și accesați „Fișier” > „Salvare ca”, nu puteți găsi formatul „Șablon Outlook” în lista „Salvare ca tip”, ci doar „Numai text” disponibil. Dar, vă vom prezenta cum să-l realizați în vrac în cele ce urmează.

Salvați în lot mai multe e-mailuri nefinalizate ca șabloane Outlook

1. De la bun început, declanșați editorul Outlook VBA.
2. În noua fereastră „Microsoft Visual Basic for Applications”, copiați și inserați codul VBA de mai jos.

Sub SaveMultipleDraftsAsTemplates()
    Dim objSelection As Outlook.Selection
    Dim i As Long
    Dim strTemplateFolder As String
    Dim objMail As Outlook.MailItem
    Dim strSubject As String
 
    'Get all selected mails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
       'Get the default folder for saving Outlook Templates
       strTemplateFolder = CStr(Environ("USERPROFILE")) & "\Documents\UserTemplates\"
 
       'Save each mail as template
       For i = objSelection.Count To 1 Step -1
           If objSelection(i).Class = olMail Then
              Set objMail = objSelection(i)
              If objMail.Subject <> "" Then
 
                 'Remove unsupported characters
                 strSubject = objMail.Subject
                 strSubject = Replace(strSubject, "/", " ")
                 strSubject = Replace(strSubject, "\", " ")
                 strSubject = Replace(strSubject, ":", "")
                 strSubject = Replace(strSubject, "?", " ")
                 strSubject = Replace(strSubject, Chr(34), " ")
 
                 objMail.SaveAs strTemplateFolder & strSubject & ".oft", olTemplate
              Else
                 objMail.SaveAs strTemplateFolder & "Template" & i & ".oft", olTemplate
              End If
           End If
       Next
 
       'Open the folder of Templates
       Shell "Explorer.exe" & " " & strTemplateFolder, vbNormalFocus
    End If
End Sub

3. După aceea, pentru comoditate ulterioară, se recomandă să atașați această macrocomandă la Bara de instrumente de acces rapid (QAT). Despre pașii detaliați, puteți citi „Cum să rulați codul VBA în Outlook
4. În cele din urmă, puteți face o fotografie urmând operațiunile de mai jos.

• La început, selectați schița de e-mailuri pentru a fi salvate ca șabloane.
• Apoi, faceți clic pe butonul macro din QAT.
• Când macro-ul se termină, se va afișa folderul Windows pentru salvarea șabloanelor Outlook implicite. Puteți vedea că șabloanele din schițele de e-mail selectate sunt acolo.

Instrumentul de reparare Inbox încă poate eșua

Când vine vorba de instrumentul intern de remediere Outlook – Scanpst, un număr mare de utilizatori îl vor aprecia. Fără îndoială, acest utilitar este într-adevăr capabil să rezolve majoritatea problemelor mici din Outlook. Cu toate acestea, nu este total impecabil. Încă poate eșua și poate aduce multe erori. De exemplu, în caz de severitate corupție Outlook, nu poate repara fișierul PST compromis. În acest scenariu, nu aveți o alternativă decât să utilizați un instrument terță parte mai puternic și de vârf, cum ar fi DataNumen Outlook Repair.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv recuperare sql și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com