Cum să exportați în loturi fotografiile și informațiile mai multor persoane de contact cu Outlook VBA

Dacă doriți să extrageți fotografiile persoanelor de contact și informațiile lor principale într-un folder de pe discul local în loturi, trebuie să utilizați Outlook VBA. Acest articol vă va învăța cum să o realizați în detaliu.

Outlook vă permite să exportați informațiile de contact prin funcția „Importați și exportați”. Puteți accesa „Fișier” > „Imprimare” > „Importare” > „Exportare într-un fișier”.

Cu toate acestea, această funcție nu vă permite să exportați fotografiile de contact. Astfel, dacă doriți să extrageți atât informațiile de contact, cât și fotografiile, trebuie să recurgeți la Outlook VBA. Următoarele sunt codurile și pașii VBA care pot salva fotografiile de contact într-un folder local specificat și pot extrage informațiile de contact într-un fișier text.

Export în lot fotografiile și informațiile mai multor persoane de contact

1. În primul rând, lansați Outlook și apăsați butoanele tastei „Alt + F11”.
2. Apoi veți avea acces la editorul VBA. Acum ar trebui să deschideți un modul care nu este în uz sau să creați un modul nou prin „Inserare” > „Modul”.
3. Ulterior, copiați și inserați următoarele coduri VBA în noul modul.

Sub BatchExportContactPhotosandInformation()
    Dim objContacts As Outlook.Items
    Dim objContact As ContactItem
    Dim strContactInfo As String
    Dim objFileSystem As Object
    Dim objTextfile As Object
    Dim objAttachments As Attachments
    Dim objAttachment As Attachment
    Dim strName As String
 
    'Specify the contacts in the default contact folder
    Set objContacts = Outlook.Application.Session.GetDefaultFolder(olFolderContacts).Items
 
    For Each objContact In objContacts
        If TypeOf objContact Is ContactItem Then
           'Get the contact's primary informtaion
           strContactInfo = "Name: " & objContact.FullName & vbCrLf & "Email: " & objContact.Email1Address & vbCrLf & "Company: " & objContact.Companies & vbCrLf & "Job Title: " & objContact.JobTitle & vbCrLf & "Business Address: " & objContact.BusinessAddress & vbCrLf & "Business Phone: " & objContact.BusinessTelephoneNumber
           'Create a Text file
           Set objFileSystem = CreateObject("Scripting.FileSystemObject")
           'You can change the folder path as per your needs
           Set objTextfile = objFileSystem.CreateTextFile("C:\Outlook Contacts\" & objContact.FullName & ".txt", True)
           objTextfile.WriteLine (strContactInfo)
 
           'Save the contact photos
           If objContact.Attachments.Count > 0 Then
              Set objAttachments = objContact.Attachments
              For Each objAttachment In objAttachments
                  If InStr(LCase(objAttachment.filename), "contactpicture.jpg") > 0 Then
                     strName = objContact.FullName & ".jpg"
                     objAttachment.SaveAsFile ("C:\Outlook Contacts\" & strName)
                  End If
              Next
           End If
       End If
    Next
End Sub

Notă: Codurile de mai sus vor exporta fotografiile și informațiile persoanelor de contact din folderul implicit de contact. Puteți schimba contactele specificate.

• Dacă doriți să exportați fotografiile și informațiile persoanelor de contact din folderul deschis în prezent, atunci ar trebui să înlocuiți „Set objContacts = …..” cu:

Set objContacts = Outlook.Application.ActiveExplorer.CurrentFolder.Items

• Dacă sperați doar să exportați fotografiile și informațiile persoanelor de contact selectate, atunci puteți utiliza următoarele rânduri:

Dim objSelection as Selection
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For each objContact in objSelection

4. După aceea, puteți închide editorul VBA și puteți continua să adăugați noul proiect la Bara de instrumente Acces rapid, ca de obicei.
5. În cele din urmă, puteți face clic pe butonul macro din Bara de instrumente Acces rapid. Imediat, fotografiile și informațiile de contact vor fi exportate în folderul specificat de pe discul local.

Puteți deschide un fișier text, în care vor fi listate informațiile principale, cum ar fi următoarea captură de ecran:

Gestionați corupția neașteptată din Outlook

Este un fapt incontestabil că Outlook este vulnerabil. Prin urmare, dacă suferiți corupție Outlook, ceea ce ar trebui să faceți în primul rând este să vă calmați. Apoi puteți continua să reparați e-mail PST corupt Outlook. Puteți folosi instrumentul de reparare inbox pentru a încerca. Dacă eșuează, atunci nu ai de ales decât să folosești un instrument mult mai puternic, cum ar fi DataNumen Outlook Repair.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv reparați baza de date SQL mdf deteriorată și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com