Cum să setați automat un timp diferit de memento pentru întâlnirile Outlook în diferite categorii de culori

Dacă clasificați întâlnirile Outlook pe categorii de culori și doriți să setați un timp diferit de memento pentru întâlniri în diferite categorii de culori, puteți consulta acest articol. Aici vă vom învăța să realizați acest lucru cu Outlook VBA.

De exemplu, împărțiți întâlnirile în două grupuri. Unul este în categoria de culoare „Offsite”, deoarece locația întâlnirii este prea departe, iar celălalt este în categoria de culoare „Onsite”, deoarece locația este chiar aici. Acum, doriți ca Outlook să poată seta automat ora de memento pentru întâlnirea „offsite” cu 1 oră înainte de începere și pentru întâlnirea „onsite” cu 15 minute înainte de începere. Având în vedere această cerință, vom împărtăși în continuare o metodă rapidă.

Setați automat un memento diferit pentru întâlniri în diferite categorii de culori

1. Pentru început, lansați aplicația Outlook.
2. Apoi, apăsați tastele „Alt + F11” pentru a accesa fereastra editorului VBA.
3. Apoi, în fereastra ulterioară, copiați și inserați codul VBA de mai jos în proiectul „ThisOutlookSession”.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Mai târziu, trebuie să faceți clic pe subrutina „Application_Startup” și să apăsați tasta „F5” pentru a rula această macrocomandă.
5. De atunci, de fiecare dată când o nouă întâlnire este adăugată la calendarul implicit sau când modificați o întâlnire existentă, Outlook va verifica automat categoriile întâlnirii și va seta automat ora de memento diferită.

Elimina erorile Outlook

Din când în când pot apărea diverse probleme cu Outlook. Prin urmare, este extrem de important ca utilizatorii să învețe cum să gestioneze problemele Outlook. Pentru început, ar fi bine să faceți copii de rezervă regulate ale datelor Outlook. În plus, dacă este posibil, se recomandă păstrarea unui cont puternic. Repararea Outlook instrument în apropiere, cum ar fi DataNumen Outlook Repair. Poate scana fișierul PST pentru a descoperi problemele Outlook și apoi le poate rezolva cu ușurință.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv recuperare sql și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com