Cum să mutați automat e-mailurile cu anumiți destinatari CC în Outlook

În realitate, majoritatea dintre voi sperați să creați o regulă Outlook pentru a muta automat e-mailurile cu destinatari specifici din CC. Însă regula Outlook nu acceptă verificarea destinatarilor din CC. Așadar, acest articol vă va învăța cum să realizați acest lucru cu Outlook VBA.

Evident, este imposibil să creați o regulă Outlook pentru a căuta anumiți destinatari CC. După cum se arată în următoarea captură de ecran, pentru e-mailurile primite, puteți verifica doar dacă propriul nume este în caseta CC. În mod similar, pentru e-mailurile trimise, chiar și nu există nicio condiție de regulă pentru a bifa caseta CC.

Prin urmare, dacă doriți să configurați Outlook pentru a muta automat e-mailurile cu anumiți destinatari CC, trebuie să căutați alte mijloace. Apoi. aici vă vom învăța cum să o realizați prin Outlook VBA.

Mutați automat e-mailurile trimise cu anumiți destinatari CC

1. În primul rând, accesați fila „Dezvoltator” și faceți clic pe butonul „Visual Basic”.
2. Apoi deschideți proiectul „ThisOutlookSession” și copiați următoarele coduri VBA în el.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

3. Ulterior, ar trebui să continuați să semnați acest cod și să modificați setările macro ca de obicei.
4. În cele din urmă, puteți ieși din fereastra „Visual Basic”. Ulterior, e-mailurile cu destinatarii CC specifici vor fi mutate în folderul de e-mail specificat.

Mutați automat e-mailurile primite cu anumiți destinatari CC

Acum că codul VBA de mai sus are scopul de a muta e-mailurile trimise cu anumiți destinatari CC, dacă doriți să căutați anumiți destinatari CC în e-mailurile primite și apoi să-l mutați, ar trebui să utilizați următoarele coduri.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Fiți bine pregătiți pentru corupția Outlook

Deși Outlook este bogat în funcții, tot nu poate fi imun la corupție. Prin urmare, ar trebui să fiți vigilenți împotriva tuturor riscurilor potențiale. Fără îndoială, pasul critic trebuie să fie realizarea unei copii de rezervă consistente și actualizate pentru datele Outlook. În plus, ar trebui să păstrați un instrument de recuperare Outlook corupt în vecinătate. Va fi util dacă atât backup-urile, cât și Scanpst.exe eșuează.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv repara SQL Server eroare fișier mdf și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com