Cum să exportați automat informațiile e-mailurilor primite într-un fișier Excel cu Outlook VBA

Mulți utilizatori speră că Outlook poate exporta automat informațiile primare ale e-mailurilor primite într-un fișier Excel. Acest articol va analiza această cerință și va introduce o metodă rapidă prin Outlook VBA.

Uneori, din anumite motive, cum ar fi statisticile de e-mail, este posibil să fie necesar să exportați e-mailurile într-un fișier Excel. În general, pentru e-mailurile primite existente, puteți utiliza pur și simplu funcția „Importați și exportați” pentru a le exporta în Excel dintr-o singură mișcare. Cu toate acestea, poate chiar doriți ca Outlook să poată exporta automat e-mailurile primite în Excel, de îndată ce ajung în căsuța dvs. poștală. Fără îndoială, nu există o astfel de caracteristică nativă în Outlook. Prin urmare, trebuie să utilizați alte abordări, cum ar fi un program de completare terță parte sau Outlook VBA. Aici vă vom învăța cum să îl faceți automat cu Outlook VBA. Citiți mai departe pentru a obține pașii și codurile corespunzătoare.

Export automat informații despre e-mailurile primite într-un fișier Excel

1. În primul rând, ar trebui să creați un fișier Excel.

• Deschideți un nou fișier Excel.
• Apoi ar trebui să tastați „Nu”. în celula A1, „Numele expeditorului” în celula B1, „Adresa de e-mail al expeditorului” în celula C1 și „Subiectul e-mailului” în celula D1 și „Timpul primit” în celula E1, ca în imaginea următoare.
• În cele din urmă, salvați-l în numele dorit și în folderul dorit.

2. După aceea, ar trebui să lansați Outlook.
3. Apoi apăsați butoanele tastei „Alt + F11”, care vă vor duce la editorul VBA.
4. Apoi, în fereastra pop-up, ar trebui să faceți dublu clic pe „ThisOutlookSession” din partea stângă.
5. Ulterior, în fereastra proiectului „ThisOutlookSession”, trebuie să copiați și să lipiți următoarele coduri VBA în ea.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. Mai târziu ar trebui să semnați acest cod.
7. Ulterior, restart Outlook pentru a activa noul proiect VBA.
8. În cele din urmă, de acum înainte, toate e-mailurile primite vor fi exportate automat în fișierul Excel prestabilit de îndată ce ajung în folderul Inbox. Fișierul excel va arăta ca următoarea imagine:

Evitați corupția dureroasă a datelor PST

Outlook a câștigat multe felicitări datorită diferitelor sale caracteristici. Cu toate acestea, nu înseamnă că este sigur. Încă poate fi compromis în orice moment. De exemplu, dacă închideți frecvent Outlook-ul incorect, este foarte probabil ca datele dvs. PST să fie puse în pericol. În acest caz, dacă doriți repara PST date, trebuie să recurgeți la un instrument cu experiență, cum ar fi DataNumen Outlook Repair.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv recupera mdf și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com