3 metode de a importa e-mailuri dintr-un folder Windows în Outlook

Poate ați salvat mai multe e-mailuri Outlook în folderul Windows. Acum, dacă doriți să le importați înapoi într-un folder Outlook, cum puteți face acest lucru? Acest articol vă va învăța 3 moduri.

După cum știm cu toții, Outlook oferă o opțiune încorporată – „Salvare ca”, prin care puteți salva e-mailurile în folderul Windows. Cu toate acestea, nu există nicio funcție pentru a adăuga din nou e-mailurile exportate înapoi în folderul Outlook. Prin urmare, dacă doriți să importați e-mailurile Outlook înapoi în Outlook, cum vă puteți da seama? În cele ce urmează, vă vom învăța 3 metode. Puteți alege oricare după preferințe.

Metoda 1: Trageți și plasați pentru a importa

1. De la bun început, trebuie să accesați folderul Windows sursă care stochează e-mailurile Outlook pentru a fi importate în Outlook.
2. Apoi, lansați aplicația Outlook.
3. Apoi deschideți folderul Outlook în care doriți să importați e-mailurile.
4. Ulterior, trebuie să restrângeți atât fereastra folderului Windows, cât și fereastra Outlook până când le puteți vizualiza între timp.
5. După aceea, în folderul Windows, puteți selecta unul dintre e-mailurile Outlook și apoi apăsați „Ctrl + A” pentru a le selecta pe toate.
6. Mai târziu, puteți glisa și plasa e-mailurile selectate în folderul Outlook vizibil, ca în următoarea captură de ecran:
7. În cele din urmă, veți vedea că toate e-mailurile Outlook au fost importate din folderul Windows în folderul Outlook, afișat ca imaginea de mai jos:

Metoda 2: Folosiți „CreateItemFromTemplate” în VBA

1. Pentru început, în fereastra principală Outlook, apăsați tastele „Alt + F11”.
2. În continuare, veți avea acces la fereastra editorului Outlook VBA.
3. Apoi copiați următorul cod VBA într-un modul gol.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

4. Apoi puteți apăsa tasta F5 în fereastra modulului curent pentru a porni macrocomanda.
5. După aceea, trebuie să navigați la folderul Windows sursă în caseta de dialog pop-up.
6. În cele din urmă, după selectarea folderului sursă, toate elementele Outlook din acel folder vor fi importate în folderul Outlook predefinit.
7. Notă: în acest fel, e-mailurile importate sunt toate e-mail-uri noi proaspete, pe care le puteți compune după cum doriți, ca în următoarea captură de ecran:

Metoda 3: Utilizați „OpenSharedItem” în VBA

1. Ca și metoda 2, copiați următoarele coduri VBA într-un alt modul.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

2. Apoi rulați această macrocomandă apăsând butonul tastei „F5”.
3. Apoi selectați folderul sursă.
4. În cele din urmă, toate e-mailurile vor fi importate ca imaginea de mai jos:

Comparații

Mijloace de a bloca corupția datelor PST

După cum știm cu toții, Outlook vine preinstalat cu un instrument încorporat - ScanpstDe cele mai multe ori, este capabil să rezolve probleme minore. Cu toate acestea, dacă problemele sunt extrem de grave, instrumentul încorporat va tinde să eșueze. Așadar, ar fi mai bine să apelați la un instrument mai puternic, cum ar fi DataNumen Outlook Repair.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv SQL Server corupţie și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com