2 moduri de a imprima listele de activități Outlook cu diferite categorii în diferite pagini

Dacă ați atribuit diverse categorii de culori sarcinilor dvs. Outlook și acum doriți să tipăriți listele de activități cu diferite categorii în diferite pagini, puteți consulta acest articol. Aici vă vom împărtăși 2 metode pentru a-l obține.

Pentru a vă clasifica și gestiona bine sarcinile, poate că ați aplicat sarcinilor dvs. categorii de culori. Acum, dacă doriți să tipăriți listele sarcinilor dvs. cu diferite categorii în pagini diferite, vă rugăm să citiți mai departe. În cele ce urmează, vă vom prezenta 2 mijloace pentru a-l obține.

Metoda 1: Imprimați manual listele de activități una câte una

1. În primul rând, în Outlook, accesați panoul „Activități”.
2. Apoi, deschideți un folder de activități.
3. Apoi, apăsați „Ctrl + E” pentru a activa panglica „Căutare”.
4. După aceea, pe fila „Căutare”, faceți clic pe butonul „Categorizare”.
5. Din lista derulantă, alegeți o categorie de culoare.
6. Apoi, numai sarcinile cu categoria selectată vor fi lăsate în listă.
7. Acum, accesați „Fișier” > „Imprimare” pentru a tipări această listă de activități.
8. Ulterior, în același mod, tipăriți manual listele de sarcini cu celelalte categorii de culori una câte una.

Metoda 2: Imprimați în serie listele de activități prin VBA

1. De la bun început, declanșați editorul VBA în conformitate cu „Cum să rulați codul VBA în Outlook".
2. Then, add the reference to “MS Excel Object Library” as per “Cum se adaugă o referință la o bibliotecă de obiecte în VBA".
3. Apoi, copiați următorul cod VBA într-un modul.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Apoi, apăsați butonul „F5” pentru a rula această macrocomandă imediat.
5. Când macro-ul se termină, listele de sarcini cu diferite categorii vor fi tipărite în pagini diferite, așa cum se arată în următoarea captură de ecran.

Obțineți date valoroase din fișierul PST compromis

Dacă sunteți supus unui fișier PST inaccesibil, următorul pas este, fără îndoială reparație PST. În acest caz, puteți încerca mai întâi instrumentul de reparare a căsuței primite. Dacă nu reușește, puteți continua să încercați un alt instrument extern, cum ar fi DataNumen Outlook Repair. Este capabil să recupereze datele PST în timp scurt.

Introducerea autorului:

Shirley Zhang este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv recupera mdf și produse software de reparații Outlook. Pentru mai multe informații vizitați www.datanumen.com