2 moduri rapide de a extrage pagini individuale din documentul Word

În postarea de astăzi, vrem să vă împărtășim 2 metode rapide de a extrage pagini individuale din documentul Word.

Uneori, într-un document Word, fiecare pagină poate conține conținut destul de independent, cum ar fi un tabel. Și, probabil, va trebui să trimiteți mese diferite unor persoane diferite. Apoi va trebui să salvați fiecare tabel care este fiecare pagină, ca fișier separat.

Prima idee care ne vine în minte ar trebui să fie clasicul copy-and-paste. Cu toate acestea, orice implică selecție poate fi enervant uneori, pentru că tragerea și selectarea pot face cu ușurință un capăt fără nicio selecție. Din acest motiv, vă recomandăm 2 metode rapide folosind macro pentru a face treaba.

Metoda 1: Extrageți pagina curentă și salvați-o ca document nou

1. În primul rând, poziționați cursorul pe pagina pe care doriți să o extrageți.
2. Faceți clic pe fila „Dezvoltator” și apoi faceți clic pe „Visual Basic” pentru a invoca editorul VBA. Dacă „Dezvoltatorul” nu este activat, apăsați pur și simplu „Alt+ F11”.
3. În al doilea rând, accesați proiectul „Normal” făcând clic pe el.
4. Apoi faceți clic pe fila „Inserare” și alegeți „Modul”.
5. Faceți dublu clic pe noul modul pentru a deschide zona de editare.
6. Apoi lipiți acolo următoarele coduri:

Sub SaveCurrentPageAsANewDoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim strFileName As String
  Dim strFolder As String
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
  strFileName = InputBox("Enter file name here: ")
 
  '  Copy current page.
  objDoc.Bookmarks("\Page").Range.Select
  Selection.Copy
 
  '  Open a new document to paste the selection.
  Set objNewDoc = Documents.Add
  Selection.Paste
 
  objNewDoc.SaveAs FileName:=strFolder & "\" & strFileName & ".docx"
  objNewDoc.Close
End Sub

7. În cele din urmă, faceți clic pe butonul „Run”.

Acum vor exista 2 casete de introducere. Introduceți calea în care doriți să stocați noul document în prima casetă de introducere. Și introduceți noul nume de document pe al doilea.

Metoda 2: Extrageți fiecare pagină și salvați-o ca document nou

Următoarea macrocomandă vă va permite să extrageți fiecare pagină individuală a unui document.

1. În primul rând, apăsați „Ctrl+ Acasă” pentru a merge la începutul documentului.
2. Apoi urmați aceiași pași din metoda 1 pentru a instala și rula o macrocomandă.
3. De data aceasta, înlocuiți macrocomanda cu aceasta:

Sub SaveEachPageAsADoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim nPageNumber As Integer
  Dim strFolder As String
  Dim objFileName As Range
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
 
  '  Copy each page in the document to paste it into a new one.
  For nPageNumber = 1 To ActiveDocument.ComputeStatistics(wdStatisticPages)
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Copy
 
    Set objNewDoc = Documents.Add
    Selection.Paste
 
    '  Save new doc with the name of "Page" & nPageNumber and get the first 20 characters of the new doc as part of the file name.
    Set objFileName = objNewDoc.Range(Start:=0, End:=20)
    objNewDoc.SaveAs FileName:=strFolder & "\" & "Page " & nPageNumber & " " & objFileName & ".docx"
    objNewDoc.Close
    Application.Browser.Next
  Next nPageNumber
End Sub

Ocupați-vă de problemele Word

Există și vor exista întotdeauna diverse probleme legate de Word. Ideea este să învățăm să le remediem corect. Cea mai recomandată metodă este, desigur, să obținem un specialist sofisticat. Recuperarea cuvintelor instrument. Ar trebui să profitați de fiecare minut pentru a vă recupera datele înainte de a fi prea târziu.

Introducerea autorului:

Vera Chen este expertă în recuperarea datelor DataNumen, Inc., care este lider mondial în tehnologiile de recuperare a datelor, inclusiv xlsx corupt și pdf repararea produselor software. Pentru mai multe informații vizitați www.datanumen.com