Como remover rapidamente destinatários duplicados do seu e-mail do Outlook com VBA

Se você adicionar grupos de contatos ao campo “Para” do e-mail atual, pode haver alguns duplicados entre eles. Este artigo ensinará como usar o VBA para remover rapidamente os destinatários duplicados.

Ao redigir um e-mail, se você não apenas adicionar contatos, mas também grupos de contatos como destinatários, às vezes pode haver alguns destinatários duplicados, pois os grupos de contatos são recolhidos por padrão. Nesse caso, se você deseja descobrir os duplicados, primeiro deve expandir os grupos de contatos e depois comparar os destinatários manualmente, o que foi apresentado detalhadamente em meu artigo anterior – “Como remover destinatários duplicados de seus e-mails do Outlook”. Sem dúvidas, é muito tedioso. Portanto, muitos usuários desejam uma maneira rápida de remover destinatários duplicados. A seguir, ensinaremos você a obtê-lo com o Outlook VBA.

Remova rapidamente destinatários duplicados em seu e-mail do Outlook

1. Em primeiro lugar, inicie seu aplicativo Outlook.
2. Em seguida, mude para a guia “Desenvolvedor” e clique no botão “Visual Basic” ou apenas pressione as teclas “Alt + F11”.
3. Em seguida, na janela “Microsoft Visual Basic for Applications”, você pode abrir um módulo em branco.
4. Posteriormente, copie e cole os seguintes códigos VBA neste módulo.

Sub RemoveDuplicateRecipients()
    Dim objCurrentMail As MailItem
    Dim objRecipients As Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
 
    Set objCurrentMail = ActiveInspector.CurrentItem
    ContactGroupFound = True
 
    While ContactGroupFound = True
          Set objRecipients = objCurrentMail.Recipients
          ContactGroupFound = False
 
          'Expand the contact groups in "To" field
          For i = objRecipients.Count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.Count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
    Wend
 
    'Remove the duplicate recipients
    For i = objRecipients.Count To 1 Step -1
        For n = (i - 1) To 1 Step -1
            If objRecipients(i).Address = objRecipients(n).Address Then
               objRecipients(i).Delete
               Exit For
            End If
        Next
    Next
End Sub

5. Depois disso, você pode adicionar o novo projeto VBA na barra de ferramentas de acesso rápido da janela de mensagem.
6. Mais tarde, você precisa definir o nível de segurança de macro do Outlook como baixo.
7. Finalmente você pode tentar.

• Primeiro, basta escrever um e-mail como de costume.
• Em seguida, adicione grupos de contatos e contatos no campo "Para".
• Em seguida, você pode clicar no novo botão de macro na Barra de Ferramentas de Acesso Rápido.
• Imediatamente, o Outlook expandirá automaticamente os grupos de contatos e removerá os destinatários duplicados.

Proteja seus valiosos dados do Outlook

Como o Outlook é propenso a travar, seus dados do Outlook são suscetíveis à corrupção. Portanto, você deve fazer muitos esforços para proteger seu arquivo do Outlook. Em primeiro lugar, você precisa fazer backup do seu arquivo PST regularmente. vai facilitar PST corrompido reparar. Além disso, é melhor preparar uma ferramenta de correção poderosa, como DataNumen Outlook Repair.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo conserto de mdf e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com