Como obter rapidamente a contagem total de subpastas em uma pasta específica no Outlook

Talvez você tenha criado um grande número de subpastas em uma determinada pasta, como Caixa de entrada, em seu Outlook. Nesse caso, se você deseja contar as subpastas, deve relutar em contar manualmente. Aqui vamos compartilhar com você uma maneira muito mais inteligente.

Para melhor classificar e arquivar itens no Outlook, muitos usuários estão acostumados a criar várias pastas e subpastas. No entanto, depois, eles podem achar um pouco difícil gerenciar muitas pastas. Nesse caso, eles podem querer contar quantas subpastas existem em uma pasta específica. Sem dúvida, é estúpido e tedioso contar manualmente. Portanto, a seguir, mostraremos um meio muito mais inteligente.

Obtenha a contagem total de subpastas em uma pasta específica

1. Para começar, abra o programa Outlook.
2. Em seguida, na janela do Outlook, você pode pressionar os botões “Alt + F11” para acessar o editor VBA.
3. Em seguida, na janela pop-up subsequente, você precisa abrir um módulo que não está sendo usado.
4. Posteriormente, copie e cole o seguinte código VBA neste módulo.

Sub CountSubfoldersUnderRootFolder()
    Dim objRootFolder As Folder
    Dim lFolderCount As Long
    Dim objFolder As Object
 
    'Get the current folder
    Set objRootFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    'If you want to select, use the following line instead
    'Set objRootFolder = Outlook.Application.Session.PickFolder
 
    If objRootFolder.Folders.count > 0 Then
       For Each objFolder In objRootFolder.Folders
           'Exclude the hidden folders under Inbox
           If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
              lFolderCount = lFolderCount + 1
 
              'Process subfolders recursively
              Call ProcessFolders(objFolder, lFolderCount)
           End If
       Next
       MsgBox lFolderCount & " subfolders under " & Chr(34) & objRootFolder.Name & Chr(34) & ".", vbInformation
    Else
       MsgBox "No subfolders under " & Chr(34) & objRootFolder.Name & Chr(34) & ".", vbInformation
    End If
End Sub
 
Sub ProcessFolders(objCurrentFolder As Object, lCount As Long)
    Dim objSubfolder As Object
 
    lCount = lCount + objCurrentFolder.Folders.count
 
    For Each objSubfolder In objCurrentFolder.Folders
        Call ProcessFolders(objSubfolder, lCount)
    Next
End Sub

5. Depois disso, você pode sair da janela atual.
6. Posteriormente, vá em “Arquivo” > “Opções” > “Barra de Ferramentas de Acesso Rápido”. Lá você pode adicionar a nova macro à Barra de Ferramentas de Acesso Rápido.
7. Finalmente, você pode tentar esta macro.

• Primeiro, selecione uma pasta cujas subpastas você gostaria de contar.
• Em seguida, clique no botão de macro na Barra de Ferramentas de Acesso Rápido.
• Imediatamente, o Outlook executará esta macro.
• Depois que a macro terminar, você receberá uma mensagem, como a imagem a seguir:

Truques para lidar com a corrupção do Outlook

O Outlook é extremamente vulnerável a vários fatores, incluindo vírus, problemas de software ou hardware, queda de energia e assim por diante. Ninguém pode garantir que é capaz de manter seu arquivo do Outlook longe da corrupção. Por isso, é essencial dominar alguns truques para lidar com danos. Em primeiro lugar, você deve fazer backup regular do PST. Além disso, você deve saber como utilizar ScanpstName, a ferramenta de reparo embutida. Por último, mas não menos importante, você deve preparar uma ferramenta externa mais robusta, como DataNumen Outlook repair.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo conserto de mdf e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com