Como encontrar rapidamente parágrafos de uma frase em seu documento do Word

Neste post, queremos mostrar a você uma maneira rápida de encontrar todos os parágrafos de uma única frase em seu documento do Word usando VBA.

De vez em quando, alguns documentos podem ter requisitos muito específicos para sua formatação e estruturas. Por exemplo, você pode não ter permissão para ter parágrafos com apenas uma frase. Esses parágrafos não são difíceis de reconhecer, mas leva tempo, especialmente se for um documento longo.

Hoje, ofereceremos a você a maneira mais rápida de especificar todos os parágrafos de uma frase em seu documento.

Encontre todos os parágrafos de uma frase em um documento

1. Em primeiro lugar, o Word conta um ponto como uma frase. Portanto, se houver palavras como "Sr." ou “Ms.”, o Word considera como uma frase. Para excluir tal distração, você precisa substituir "Sr." com “Sr”. E quando terminar de encontrar o parágrafo de uma única frase, você pode alterá-los de volta. Para substituir palavras, você pode consultar este link: Como localizar e substituir vários itens em seu documento do Word
2. Em segundo lugar, pressione “Alt+ F11” para acionar o editor VBA.
3. Em seguida, clique em projeto “Normal”.
4. Clique na guia "Inserir" na barra de menu e escolha "Módulo" no menu suspenso.
5. Em seguida, clique duas vezes no módulo para abri-lo.
6. Cole os seguintes códigos no módulo:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Por último, mas não menos importante, clique no botão “Executar” ou pressione “F5”.

Você receberá uma caixa de mensagem, informando que o trabalho está concluído.

Localizar todos os parágrafos de uma frase em vários documentos

1. Para começar, você precisa colocar todos os documentos de destino em uma pasta.
2. Em seguida, instale e execute a macro abaixo:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Na janela “Browse” aberta, escolha a pasta onde guarda os documentos e clique em “OK”.

A macro então destacará todos os parágrafos de uma frase e deixará os documentos abertos. Se um documento não contiver um parágrafo de uma frase, ele será fechado. Além disso, há uma caixa de mensagem, indicando o número de parágrafos de uma frase em cada documento.

Lidar com Incidente de Perda de Dados

Erros do usuário e queda repentina de energia podem resultar na morte do Word. Enquanto uma palavra recolhida pode não apenas afetar o trabalho diário, mas também levar a danos do documentoIsso não é, de forma alguma, a parte mais irritante de um desastre de dados. É melhor usar um programa de reparo para recuperar os dados imediatamente.

Introdução do autor:

Vera Chen é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo recuperar excel e pdf reparar produtos de software. Para mais informações visite www.datanumen.com