Como excluir rapidamente destinatários “CC” originais ao usar “Responder a todos” no Outlook

Ao usar “Responder a todos”, o e-mail de resposta também incluirá os destinatários “CC” do e-mail original no campo “CC”. Mas, se você deseja excluir esse tipo de destinatário, pode usar o método apresentado neste artigo.

Às vezes, você deseja responder um e-mail ao remetente original e aos destinatários “Para”. Nesse cenário, você definitivamente pensará em usar a opção “Responder a todos”. No entanto, desta forma, se o e-mail original também tiver destinatários “CC”, o e-mail “Responder a todos” copiará automaticamente os destinatários “CC” para o campo “CC”. Se você não quiser respondê-los, terá que removê-los manualmente, o que é um pouco problemático. Agora, a seguir, ensinaremos como permitir que o Outlook faça isso automaticamente de acordo com suas necessidades.

Exclua rapidamente os destinatários “CC” originais ao usar “Responder a todos”

1. Para comotart, inicie o Outlook.
2. Em seguida, acesse o editor VBA lendo o artigo anterior – “Como executar o código VBA no seu Outlook".
3. Em seguida, copie o seguinte código VBA para o projeto “ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when you click "Reply All"
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objRecipient As Outlook.Recipient
    Dim i As Long
 
    'Ask you if to exclude CC recipients
    If MsgBox("Do you want to exclude original CC recipients? " , vbQuestion + vbYesNo) = vbYes Then
       'If select Yes, remove CC recipients
       For i = Response.Recipients.Count To 1 Step -1
           If Response.Recipients(i).Type = olCC Then
              Response.Recipients.Remove (i)
           End If
       Next
    End If
End Sub

4. Posteriormente, restart seu Outlook para ativar este novo projeto.
5. Desde então, toda vez que você clicar no botão “Responder a todos”, receberá uma solicitação, conforme mostrado na imagem a seguir, perguntando se deseja excluir os destinatários CC originais.
6. Se você selecionar “Sim”, o Outlook removerá automaticamente os destinatários no campo “CC”.

Mantenha-se bem preparado para danos no Outlook

Como todos sabemos, ninguém pode garantir 100% que pode ser imune aos danos do Outlook. Portanto, é essencial que todos os usuários regulares do Outlook tomem muitas precauções. Em primeiro lugar, um dos most os imperativos é manter um backup de dados do Outlook consistente e atualizado. Então, é necessário aprender a usar a ferramenta de reparo da caixa de entrada. Por último, mas não menos importante, é prudente e recomendável manter um profissional experiente Correção do Outlook ferramenta nas proximidades, como DataNumen Outlook Repair.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo recuperar mdf e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com