Como Anexar Rapidamente os Slides Específicos de um PowerPoint Apresentação para o seu e-mail do Outlook

Se você deseja extrair os slides específicos de um PowerPoint apresentação para uma nova apresentação separada e anexá-la a um e-mail do Outlook, você pode utilizar o caminho compartilhado neste artigo.

Em vez de anexar um inteiro PowerPoint apresentação para um e-mail, se você deseja anexar os slides específicos da apresentação, em geral, você precisa primeiro copiar os slides específicos para uma nova apresentação. É muito problemático. Portanto, aqui mostraremos um método que pode realizá-lo de uma só vez.

Anexe os slides específicos de um PowerPoint Apresentação para um e-mail

1. Primeiro, abra o específico PowerPoint apresentação.
2. Então, no PowerPoint janela do aplicativo, pressione as teclas “Alt + F11” para acessar o editor VBA.
3. Em seguida, na nova janela, crie um novo módulo pressionando “Inserir” > “Módulo”.
4. Posteriormente, copie e cole o seguinte código VBA neste módulo.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Depois disso, você pode fechar a janela atual.
6. Posteriormente, vá em “Arquivo” > “Opções” > “Barra de Ferramentas de Acesso Rápido” para adicionar a nova macro à Barra de Ferramentas de Acesso Rápido.
7. Finalmente, você pode tentar esta macro.

• Para começar, selecione os slides específicos que deseja extrair.
• Em seguida, clique no botão de macro na Barra de Ferramentas de Acesso Rápido.
• Imediatamente, um e-mail do Outlook aparecerá, no qual há um PowerPoint apresentação que é extraída da apresentação de origem.

Utilize uma ferramenta de recuperação eficaz

Como todos sabemos, o Outlook é dotado de um utilitário de reparo integrado – ScanpstName. No entanto, ele pode simplesmente lidar com pequenas falhas no Outlook. Se o que você enfrenta é um dano sério, ele não produzirá efeitos. Nesse ponto, você não tem escolha a não ser recorrer a outra ferramenta de reparo poderosa e confiável, como DataNumen Outlook Repair. Com ele, você será capaz de resgatar seu arquivo corrompido do Outlook.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo mdf corrompido e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com