Como anexar rapidamente o último arquivo modificado em uma pasta do Windows ao seu e-mail do Outlook

Às vezes, você pode querer localizar e anexar rapidamente o último arquivo modificado em uma pasta específica do Windows a um e-mail do Outlook. Nesse caso, você pode utilizar o método apresentado neste artigo.

Alguns usuários desejam que o Outlook detecte e anexe rapidamente o último arquivo modificado em uma pasta do Windows a um e-mail, como o arquivo criado, alterado ou salvo mais recentemente. No entanto, o Outlook não oferece esse recurso nativo e direto. Portanto, a seguir, apresentaremos um trecho de código VBA que pode realizar essa tarefa com facilidade.

Anexe o último arquivo modificado em uma pasta do Windows ao e-mail

1. No início, você deve iniciar seu aplicativo Outlook.
2. Então, depois de entrar na janela principal do Outlook, você pode pressionar os botões de tecla “Alt + F11”.
3. Em seguida, você acessará a janela do editor VBA do Outlook com sucesso.
4. Posteriormente, você deve encontrar e abrir um módulo que não está sendo usado.
5. E então copie e cole o seguinte código VBA nesta janela do módulo.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Depois disso, você pode sair da janela atual do editor VBA e prosseguir para adicionar a nova macro à Barra de Ferramentas de Acesso Rápido ou à faixa de opções da janela Mensagem.
7. Posteriormente, você precisará alterar o nível de segurança de macro do Outlook para baixo.
8. Eventualmente, você pode tentar.

• Em primeiro lugar, crie e redija um novo e-mail do Outlook como de costume.
• Em seguida, pressione o botão macro na Barra de Ferramentas de Acesso Rápido, como na imagem abaixo:
• Em seguida, você será solicitado a selecionar uma pasta de origem do Windows e clicar em “OK”.
• Se houver tal arquivo na pasta selecionada do Windows, você receberá um prompt como a seguinte captura de tela:
• Quando você clicar em “Sim”, este arquivo será anexado de uma só vez.

Resolva os problemas do Outlook o mais rápido possível

Sempre que você encontrar algum problema do Outlook, é recomendável resolvê-lo o mais rápido possível. Nesta situação, é melhor preparar um robusto Correção do Outlook ferramenta com antecedência, como DataNumen Outlook Repair. Ele é capaz de corrigir erros de PST e resgatar seus dados do Outlook de forma eficaz.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo mdf corrompido e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com