Como definir um tempo de lembrete padrão diferente para diferentes tipos de itens sinalizados em seu Outlook

Por padrão, o Outlook usará automaticamente o tempo de lembrete padrão das tarefas para todos os tipos de itens sinalizados. No entanto, se você quiser usar um tempo de lembrete diferente para itens sinalizados com base no tipo de item, consulte o método apresentado neste artigo.

O Outlook permite que você defina o tempo de lembrete padrão para todos os itens sinalizados, independentemente do tipo de item. Você pode ir ao menu "Arquivo" e clicar em "Opções". Em seguida, na janela “Opções do Outlook”, você pode ver a opção “Horário padrão do lembrete” na guia “Tarefas”, conforme mostrado na captura de tela a seguir.

No entanto, a maioria dos usuários deseja usar horários de lembrete diferentes para diferentes tipos de itens sinalizados, como "9:00" para e-mails sinalizados e "17:30" para contatos sinalizados. A seguir, nos concentraremos neste exemplo para apresentar um método.

Definir tempo de lembrete padrão diferente para diferentes tipos de itens sinalizados

1. Para começar, abra o aplicativo Outlook.
2. Em seguida, acesse o editor VBA do Outlook com referência a “Como executar o código VBA no seu Outlook".
3. Na janela “Microsoft Visual Basic for Applications” subsequente, copie o seguinte código para o projeto “ThisOutlookSession”.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Em seguida, reinicie o Outlook para ativar essa macro.
5. A partir de agora, toda vez que você sinalizar um e-mail, o horário do lembrete será definido para “10:00” na data de vencimento da sinalização.
6. E quando você sinalizar um contato, o horário do lembrete será definido como “17:30” na data de vencimento do sinalizador.

Resolva os problemas do Outlook com flexibilidade

Você pode se deparar com diversos problemas no Outlook. Portanto, é importante aprender algumas medidas preventivas para lidar com eles. Por exemplo, se o Outlook reinicia com frequência, você pode tentar reparar o Office ou desativar os suplementos de terceiros, etc. Ou, se o seu arquivo PST do Outlook estiver comprometido, você pode primeiro tentar... ferramenta de reparo da caixa de entrada. Quando falha, pode continuar a recorrer a uma poderosa ferramenta externa, como DataNumen Outlook Repair.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo recuperação mdf e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com