Como marcar compromissos de fim de semana automaticamente como privados no Outlook

Formatoost usuários, os atendimentos agendados no final de semana costumam ser particulares. Portanto, eles desejam que o Outlook marque e mostre automaticamente esses compromissos como privados. Neste artigo, tornaremos isso realidade com um pouco de script.

Para distinguir mais facilmente os compromissos comerciais dos privados, o Outlook permite que os usuários marquem os compromissos como privados. Dessa forma, você achará muito conveniente e fácil imprimir o calendário sem compromissos particulares. Nesta situação, você pode desejar que seu Outlook reconheça e marque automaticamente compromissos específicos como privados. Por exemplo, geralmente, os compromissos no fim de semana são privados, portanto, você deseja permitir que o Outlook os marque automaticamente como privados. A partir daí, vamos orientá-lo a alcançá-lo.

Marcar compromissos de fim de semana automaticamente como privados

1. Primeiro, inicie o editor VBA do Outlook de acordo com “Como executar o código VBA no seu Outlook".
2. Em seguida, na janela “Microsoft Visual Basic for Applications”, coloque o seguinte código no projeto “ThisOutlookSession”.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call MarkWeedendAppointmentPrivate(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "Start" Or Name = "End" Then
       Call MarkWeedendAppointmentPrivate(objAppointment)
    End If
End Sub

Private Sub MarkWeedendAppointmentPrivate(ByVal objAppointment As Outlook.AppointmentItem)
    Dim dStartDate As Date
 
    dStartDate = Format(objAppointment.Start, "Short Date")
 
    'If the appointment start falls on weekend
    Select Case Weekday(dStartDate)
           Case 7, 1
                'Mark it private
                objAppointment.Sensitivity = olPrivate
    End Select
End Sub

3. Depois disso restart Outlook para ativar a macro.
4. A partir de agora, sempre que você criar um novo compromisso ou alterar um compromisso existente para o fim de semana, o Outlook o marcará automaticamente como privado.

Resolva problemas irritantes do Outlook

É possível que você tenha encontrado alguns problemas ao lidar com o Outlook, como congelamento inesperado de aplicativos, mensagens de erro pop-up e assim por diante. Ao sofrê-los, você ficaria preocupado. Por favor acalme-se! O pânico não ajudará em nada, mas piorará o caso. Em primeiro lugar, você pode verificar se consegue acessar o arquivo PST normalmente. Nesse caso, você deve reparar o arquivo PST, o que pode ser feito através do ferramenta de reparo da caixa de entrada ou uma ferramenta externa mais poderosa, como DataNumen Outlook Repair.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo conserto de mdf e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com