Como enviar todos os arquivos em lote em uma pasta do Windows por meio de e-mails separados do Outlook

Se você deseja enviar todos os arquivos em uma pasta do Windows por e-mails individuais do Outlook para alguém, pode usar o método apresentado neste artigo. Está fazendo uso de código VBA, que é bastante eficaz.

Depois de ler meu artigo anterior – “3 métodos rápidos para anexar todos os arquivos em uma pasta local a um e-mail do Outlook”, alguns usuários desejam enviar todos os arquivos em uma pasta local por e-mails separados. De maneira padrão, você deve criar e-mails e anexar os arquivos um por um. É bastante problemático. Portanto, a seguir, apresentaremos uma maneira mais eficaz para você.

Lote Enviar todos os arquivos em uma pasta do Windows por meio de e-mails separados

1. Primeiramente, abra o programa Outlook.
2. Em seguida, no Outlook, acesse o editor VBA em referência ao artigo – “Como executar o código VBA no seu Outlook".
3. Em seguida, copie e cole o seguinte código VBA em um projeto ou módulo.

Sub SendAllFilesInSeparateEmails()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFile As Object
    Dim strWindowsFolder As String
    Dim objFileSystem As Object
    Dim objMail As Outlook.MailItem
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       Set objWindowsFolder = objFileSystem.GetFolder(strWindowsFolder)
 
       'Send each file in an email
       For Each objFile In objWindowsFolder.Files
 
           'Create a new mail
           Set objMail = Outlook.Application.CreateItem(olMailItem)
           'Change the details as per your needs
           With objMail
                .Subject = Left(objFile.Name, Len(objFile.Name) - (Len(objFileSystem.GetExtensionName(objFile.Name)) + 1))
                .Attachments.Add objFile.Path
                .Recipients.Add ("someone@datanumen.com")
                .Recipients.ResolveAll
                .Send
          End With
       Next
 
       'Prompt you when completing sending
       MsgBox "All done!", vbOKOnly + vbExclamation
    End If
End Sub

4. Depois disso, você pode executar esta macro de uma só vez. Basta pressionar o botão de tecla "F5".
5. Posteriormente, você deverá selecionar a pasta de origem do Windows na caixa de diálogo pop-up.
6. Em última análise, o Outlook anexará todos os arquivos nesta pasta do Windows para separar os e-mails e enviar os e-mails para o destinatário predefinido.
7. Quando terminar, você receberá uma mensagem dizendo “Tudo pronto!”.

Fique de olho na integridade do Outlook

Embora o Outlook seja considerado o cliente de e-mail mais popular do mercado, ele ainda apresenta uma falha grave: sua vulnerabilidade. Em outras palavras, o Outlook é propenso a diversos erros e corrupção. Portanto, você deve dar muita importância à integridade do seu Outlook, protegendo-o contra danos. Além disso, é necessário fazer backup dos seus arquivos do Outlook regularmente. Recomenda-se também o uso de uma ferramenta de reparo de arquivos PST, como [nome da ferramenta/serviço]. DataNumen Outlook Repair. Pode reparar o Outlook questões sem quaisquer aborrecimentos.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo correção de sql e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com