Como mover automaticamente os e-mails com destinatários CC específicos no Outlook

Na realidade, muitos de vocês podem desejar criar uma regra do Outlook para mover automaticamente os e-mails com destinatários em cópia (CC) específicos. Mas as regras do Outlook não permitem verificar destinatários em CC. Portanto, este artigo ensinará como fazer isso com VBA do Outlook.

Obviamente, é impossível criar uma regra do Outlook para pesquisar destinatários CC específicos. Conforme mostrado na captura de tela a seguir, para e-mails recebidos, você só pode verificar se seu próprio nome está na caixa CC. Da mesma forma, para e-mails enviados, mesmo que não haja condição de regra para marcar a caixa CC.

Portanto, se você deseja configurar o Outlook para mover os e-mails com destinatários CC específicos automaticamente, deve procurar outros meios. Então. aqui ensinaremos como conseguir isso por meio do Outlook VBA.

Mover automaticamente os e-mails enviados com destinatários CC específicos

1. Em primeiro lugar, vá para a guia “Desenvolvedor” e clique no botão “Visual Basic”.
2. Em seguida, abra o projeto “ThisOutlookSession” e copie os seguintes códigos VBA para ele.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

3. Posteriormente, você deve assinar este código e alterar as configurações de macro como de costume.
4. Por fim, você pode sair da janela “Visual Basic”. Depois disso, os e-mails com os destinatários CC específicos serão movidos para a pasta de e-mail especificada.

Mover automaticamente os e-mails recebidos com destinatários CC específicos

Agora que o código VBA acima visa mover e-mails enviados com destinatários CC específicos, se você quiser procurar destinatários CC específicos em e-mails recebidos e movê-los, use os seguintes códigos.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Mantenha-se bem preparado para a corrupção do Outlook

Embora o Outlook seja rico em recursos, ele ainda não pode ser imune à corrupção. Portanto, você deve manter-se vigilante contra todos os riscos potenciais. Sem dúvida, a etapa crítica deve ser fazer um backup consistente e atualizado dos dados do Outlook. Além disso, você deve manter um ferramenta de recuperação do Outlook corrompida nas proximidades. Ele será útil se os backups e o Scanpst.exe falharem.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo reparar SQL Server erro de arquivo mdf e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com