Como aplicar automaticamente as categorias de um e-mail a todas as suas respostas e encaminhamentos no Outlook

Ao responder ou encaminhar um e-mail, você pode querer aplicar as mesmas categorias. Neste artigo, vamos ensiná-lo a realizar isso com código VBA.

Se você está acostumado a atribuir as mesmas categorias de cores do e-mail original a todas as suas respostas e encaminhamentos, por que não permite que o Outlook faça isso automaticamente? Mesmo que o Outlook não forneça um recurso tão direto, você ainda pode obtê-lo com a ajuda do código VBA. A seguir, iremos expor as etapas detalhadas e o código para você.

Aplicar automaticamente as categorias de um e-mail a todas as suas respostas e encaminhamentos

1. No início, inicie o aplicativo Outlook.
2. Em seguida, pressione as teclas “Alt + F11” para executar o editor VBA do Outlook.
3. Em seguida, copie o seguinte código VBA para o projeto “ThisOutlookSession”.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

4. Em seguida, reinicie o Outlook para ativar este projeto.
5. Desde então, você pode experimentá-lo seguindo as etapas abaixo.

• Primeiro, selecione um e-mail e clique no botão "Avançar".
• Em seguida, um e-mail de encaminhamento será exibido, no qual você pode mudar para a guia “Opções” e clicar no ícone de extensão no canto inferior direito do grupo “Mais opções”.
• Em seguida, na caixa de diálogo pop-up “Propriedades”, você pode ver que este e-mail está atribuído com as mesmas categorias de cores do e-mail original.

Corrigir arquivo danificado do Outlook

Dado o fato de que o Outlook é vulnerável, você deve tomar várias ações para evitar a perda de dados do Outlook. Por exemplo, você precisa fazer backups periódicos de dados. Além disso, é necessário tomar cuidado com e-mails desconhecidos, incluindo links ou anexos incorporados. Por último, mas não menos importante, você deve obter uma ferramenta de correção externa de ponta, como DataNumen Outlook Repair. É capaz de ajudá-lo a recuperar o máximo de dados de Outlook corrompido arquivo.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo SQL Server fixo e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com