3 maneiras de inserir rapidamente quebras de seção em seu documento do Word

Neste artigo, vamos nos concentrar em mostrar a você 3 maneiras de inserir rapidamente quebras de seção em seu documento do Word.

As quebras de seção são úteis para dividir um documento em seções, capítulos, etc. Além disso, inserir quebras de seção é uma parte indispensável da configuração de diferentes cabeçalhos ou rodapés em diferentes páginas.

Normalmente, teremos que navegar até a página e localizar o cursor na posição adequada. Em seguida, clique em “Layout da página” e “Quebras”. Em seguida, escolha um tipo de quebra de seção no menu suspenso. Tal processo pode ser tedioso às vezes. Portanto, queremos salvá-lo da rotina habitual e adotar uma solução rápida e suja.

Método 1: inserir uma quebra de seção em uma página específica

1. Primeiro de tudo, pressione “Alt+F11” no Word para invocar o editor VBA.
2. Em seguida, crie um novo módulo clicando em “Normal” na coluna da esquerda.
3. Em seguida, clique na guia "Inserir" na barra de menu.
4. E escolha “Módulo” no menu suspenso de “Inserir”.
5. Clique duas vezes no novo módulo para abri-lo.
6. Cole a seguinte macro na área de codificação:

Sub InsertBreakOnSpecificPage()
  Dim strPageNum As String
  Dim nPageNum As Integer
 
  strPageNum = InputBox("Enter a page number: ")
  nPageNum = Int(strPageNum)
 
  Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nPageNum
  ActiveDocument.Bookmarks("\page").Range.Select
  Selection.Collapse wdCollapseEnd
  Selection.InsertBreak Type:=wdSectionBreakContinuous
End Sub

7. Agora, clique em “Executar” ou pressione “F5” para executar os códigos.
8. Em seguida, digite o número da página desejada na caixa de diálogo. E clique em “OK” para prosseguir.

Até agora, você inseriu uma quebra de seção no final da página 2.

Observação:

Se você quiser separar várias páginas consecutivas como uma seção com o uso de quebras de seção, será necessário inserir a quebra de seção duas vezes, uma no final da última página da seção anterior e outra no final da última página desta nova seção .

Nesse caso, ao inserir a primeira quebra, lembre-se de inserir o número correto que é o número da página da última página da seção anterior.

Método 2: inserir uma quebra de seção em cada página de um documento

1. Em primeiro lugar, instale e execute uma macro seguindo exatamente as etapas acima.
2. Em seguida, substitua a macro por esta:

Sub InsertBreakOnEachPage()
  Dim nTotalPageNumber As Integer
 
  For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Collapse wdCollapseEnd
    Selection.InsertBreak Type:=wdSectionBreakContinuous
  Next
End Sub

Esta macro insere uma quebra de seção no final de cada página do documento atual.

Método 3: inserir uma quebra de seção em cada página de vários documentos

1. Para começar, coloque todos os documentos que deseja editar na mesma pasta.
2. Da mesma forma, instale e execute a macro com as instruções adequadas.
3. Desta vez, use estes códigos:

Sub InsertBreaksIntoMultiDoc()
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nTotalPageNumber As Integer
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "No folder is selected! Please select the target folder."
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
      Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
      Application.Browser.Target = wdBrowsePage
      ActiveDocument.Bookmarks("\page").Range.Select
      Selection.Collapse wdCollapseEnd
      Selection.InsertBreak Type:=wdSectionBreakContinuous
    Next
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. A macro deve acionar a janela “Browse”. Escolha a pasta onde guarda os documentos e clique em “OK”.

O processo não deve demorar mais do que alguns segundos.

Ferramenta útil para corrupção de documentos

É uma experiência frustrante encontrar documentos danificados. Nesse cenário, uma ferramenta boa e confiável que pode ajudar palavra de reparação os documentos poderão aliviar muito a ansiedade. Portanto, você precisa ser extremamente cauteloso ao escolher uma ferramenta de reparo. Uma utilidade insuficiente pode causar mais danos.

Introdução do autor:

Vera Chen é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo Recuperação do Excel e pdf reparar produtos de software. Para mais informações visite www.datanumen.com