3 métodos úteis para limpar em lote todos os estilos de tabela em seu documento do Word

Neste artigo, vamos nos concentrar em demonstrar a você 3 métodos úteis para limpar em lote todos os estilos de tabela em seu documento do Word.

De vez em quando, se uma tabela do Word for aplicada com um estilo indesejado ou reduzir o efeito visual de todo o documento, você precisará limpar seu estilo. Agora vamos mostrar como realizar tal tarefa.

Método 1: Limpar o estilo da tabela de uma palavra

1. Em primeiro lugar, mova o cursor sobre a tabela desejada até que o sinal de "x" apareça no canto superior esquerdo da tabela.
2. Em seguida, clique no sinal de cruz para selecionar a tabela inteira.
3. Agora você acionou as “Ferramentas de Tabela”. Clique na guia "Design".
4. Em seguida, clique no botão “Mais” no grupo “Estilos de tabela” para mostrar o menu suspenso.
5. Escolha a opção “Limpar”.
6. Agora o estilo da tabela foi removido. Assim como todas as bordas da tabela. Para adicionar bordas à tabela, verifique se a tabela está selecionada. E clique no botão suspenso ao lado do comando “Borders”.
7. E escolha “Todas as bordas”.

Aqui está o resultado:

Método 2: limpar em lote todos os estilos de tabela em um documento

Depois de fazer a tabela única, o tópico do processamento em lote não pode ser perdido. Primeiro, vamos ver como limpar todos os estilos de tabela em um documento via VBA.

1. Para começar, pressione “Alt + F11” para exibir o editor VBA no Word.
2. Em seguida, clique no projeto “Normal” na coluna da esquerda.
3. Em seguida, clique em “Inserir” na barra de menu.
4. E escolha “Módulo” no menu suspenso.
5. Abra o espaço de codificação do módulo clicando duas vezes nele.
6. Agora cole a seguinte macro lá:

Sub ClearTableStylesInADoc()
  Dim objTable As Table
  Dim objDoc As Document
 
  Application.ScreenUpdating = False
  Set objDoc = ActiveDocument
 
  For Each objTable In objDoc.Tables
    objTable.Style = "Table Normal"
    objTable.Borders.Enable = True
  Next objTable
 
  Application.ScreenUpdating = True
 
  Set objDoc = Nothing
End Sub

7. Por fim, clique em “Executar”.

Esta macro limpa todos os estilos de tabela em um documento, aplica o estilo “Tabela Normal” a eles e também adiciona bordas de tabela.

Método 3: limpar em lote todos os estilos de tabela em vários documentos

Agora, caso você tenha alguns documentos para lidar, aqui está a macro para limpar todos os estilos de tabela em vários documentos.

1. Em primeiro lugar, organize todos os documentos em uma pasta.
2. Repita as etapas no método 2 para instalar e executar uma macro.
3. Só que desta vez, lembre-se de substituir por esta macro:

Sub ClearTableStylesInMultiDoc()
  Dim objTable As Table
  Dim objDoc As Document
  Dim StrFolder As String
  Dim strFile As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first."
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
 
    For Each objTable In objDoc.Tables
      objTable.Style = "Table Normal"
      objTable.Borders.Enable = True
    Next objTable
 
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. Executando a macro, haverá a janela “Browse”. Selecione a pasta onde você armazena o documento na etapa 1 e clique em “OK”.

Deixe o resto do trabalho para a macro então.

Formas de recuperar documentos perdidos

Por documentos perdidos, queremos dizer que os documentos foram comprometidos devido a Corrupção de palavras ou erros humanos. Ao lidar com esses documentos, você deve sempre ter em mente que eles podem ser recuperados com a ajuda de alguma ferramenta de reparo avançada.

Introdução do autor:

Vera Chen é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo reparar xls e pdf reparar produtos de software. Para mais informações visite www.datanumen.com