3 métodos para importar e-mails de uma pasta do Windows para o Outlook

Talvez você tenha salvo vários e-mails do Outlook em sua pasta do Windows. Agora, se você deseja importá-los de volta para uma pasta do Outlook, como pode fazer isso? Este artigo vai te ensinar 3 maneiras.

Como todos sabemos, o Outlook oferece uma opção integrada – “Salvar como”, com a qual você pode salvar os e-mails na pasta do Windows. No entanto, não há nenhum recurso para você adicionar novamente os e-mails exportados à pasta do Outlook. Portanto, se você deseja importar os e-mails do Outlook de volta para o Outlook, como pode fazê-lo? A seguir, ensinaremos 3 métodos. Você pode escolher qualquer um conforme sua preferência.

Método 1: Arraste e Solte para Importar

1. No início, você precisa acessar a pasta de origem do Windows que está armazenando os e-mails do Outlook a serem importados para o Outlook.
2. Em seguida, inicie seu aplicativo Outlook.
3. Em seguida, abra a pasta do Outlook para a qual você deseja importar os e-mails.
4. Posteriormente, você precisa restringir a janela da pasta do Windows e a janela do Outlook até poder visualizá-las enquanto isso.
5. Depois disso, na pasta do Windows, você pode selecionar um dos e-mails do Outlook e pressionar “Ctrl + A” para selecionar todos eles.
6. Mais tarde, você pode arrastar e soltar os e-mails selecionados para a pasta visível do Outlook, como na captura de tela a seguir:
7. Por fim, você verá que todos os e-mails do Outlook foram importados da pasta do Windows para a pasta do Outlook, conforme a imagem abaixo:

Método 2: Use “CreateItemFromTemplate” no VBA

1. Para começar, na janela principal do Outlook, pressione as teclas “Alt + F11”.
2. Em seguida, você terá acesso à janela do editor VBA do Outlook.
3. Em seguida, copie o seguinte código VBA em um módulo em branco.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

4. Em seguida, você pode pressionar a tecla F5 na janela do módulo atual para iniciar a macro.
5. Depois disso, você precisa navegar até a pasta de origem do Windows na caixa de diálogo pop-up.
6. Por fim, depois de selecionar a pasta de origem, todos os itens do Outlook nessa pasta serão importados para a pasta predefinida do Outlook.
7. Nota: desta forma, os e-mails importados são todos e-mails novos, que você pode compor à vontade, como na captura de tela a seguir:

Método 3: Utilizar “OpenSharedItem” no VBA

1. Como no Método 2, copie os seguintes códigos VBA em outro módulo.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

2. Em seguida, execute esta macro pressionando o botão de tecla “F5”.
3. Em seguida, selecione a pasta de origem.
4. Eventualmente todos os e-mails serão importados conforme imagem abaixo:

Comparações

Meios para bloquear a corrupção de dados PST

Como todos sabemos, o Outlook vem pré-instalado com uma ferramenta embutida – ScanpstNameNa maioria das vezes, ele consegue resolver problemas pequenos. No entanto, se os problemas forem muito graves, a ferramenta integrada tende a falhar. Portanto, é melhor recorrer a uma ferramenta mais potente, como... DataNumen Outlook Repair.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo SQL Server corrupção e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com