2 maneiras rápidas de encontrar ou excluir frases contendo texto específico em sua palavra

Neste artigo, oferecemos 2 maneiras rápidas de encontrar ou excluir frases que contenham um texto específico em seu Word.

É sabido que podemos usar a função "Localizar e Substituir" no Word para encontrar facilmente todas as ocorrências de palavras específicas. Depois, não teremos problemas em destacá-las, substituí-las ou removê-las. Como você pode ver, o alvo é uma palavra ou frase. Hoje, porém, temos o prazer de apresentar a você uma maneira de usar macros para encontrar ou excluir frases que contenham determinado texto.

Método 1: localizar ou excluir frases contendo texto específico

1. Para começar, pressione “Alt+F11” para acionar o editor VBA no Word.
2. Em seguida, crie um novo módulo clicando em “Normal”.
3. Em seguida, clique em “Inserir” e escolha “Módulo” para obter um novo.
4. E abra o módulo com um clique duplo.
5. Agora cole os seguintes códigos:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. A seguir clique em “Executar”.
7. Haverá uma caixa de entrada, solicitando que você digite o texto. Basta digitar o texto comum que todas as frases contêm. Clique OK".
8. Em seguida, você verá uma frase contendo o texto selecionado com uma caixa de mensagem sendo exibida. Clique em “Sim” para deletar a frase e em “Não” para mantê-la.
9. Após a confirmação, a próxima frase com o texto selecionado é exibida. E há também a caixa de confirmação. Ou seja, a macro percorre todo o documento, encontrando as frases-alvo e solicitando sua confirmação a cada vez.

Método 2: localizar ou excluir frases contendo qualquer texto em uma lista

Com a macro do método 1, você só pode pesquisar uma palavra ou frase por vez. Certamente, você pode executar a macro repetidamente para pesquisar várias ocorrências de palavras ou frases. Para atender à necessidade de busca múltipla, forneceremos outra macro.

1. Primeiro, coloque todos os textos desejados em um novo documento. Certifique-se de que cada trecho de texto ocupe um parágrafo inteiro, sem espaços em branco no final. Feche e salve o documento.
2. Em seguida, instale e execute uma macro com as etapas exatas do método 1.
3. Em seguida, substitua a macro por esta:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Agora a janela “Browse” será aberta. Escolha o documento que acabou de salvar e clique em “Abrir”.
5. O procedimento a seguir é o mesmo do método 1.

Abordagem para Lidar com Documentos Corrompidos

A perda de dados valiosos é absolutamente devastadora. Pode até mesmo deixar seu negócio em risco. Para evitar tal frustração, você precisa se apossar de um Correção de palavras ferramenta o mais rápido possível. Essa ferramenta deve ajudá-lo a vencer a batalha contra a corrupção de documentos.

Introdução do autor:

Vera Chen é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo corrigir Excel e pdf reparar produtos de software. Para mais informações visite www.datanumen.com