2 maneiras rápidas de extrair seções do seu documento do Word

Neste artigo, oferecemos 2 maneiras rápidas e fáceis de extrair seções de seu documento do Word para outro ou vários.

Acontece com bastante frequência extrair o conteúdo de um documento para outro. E em nosso artigo anterior, discutimos como extrair páginas de um documento. Para informações detalhadas, você pode consultar este artigo: 2 maneiras rápidas de extrair páginas individuais do seu documento do Word

Hoje, mostraremos como extrair por seção.    

Método 1: extrair a seção atual para um novo documento

1. Em primeiro lugar, posicione o cursor em um tarobter seção.
2. Em seguida, pressione “Alt + F11” para invocar o editor VBA no Word.
3. Em seguida, na coluna da esquerda, clique em “Normal”.
4. E na barra de menu, clique em “Inserir”.
5. Em seguida, escolha “Módulo” no menu suspenso.
6. Clique duas vezes para abrir o novo módulo e cole os seguintes códigos lá:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Em seguida, clique em “Executar” na barra de menu ou pressione “F5”.
8. Em seguida, aparecerá a janela "Browse". Escolha um local para armazenar o novo documento e clique em “OK”.
9. E na caixa “Nome do arquivo”, digite o nome do novo arquivo e clique em “OK”.

Agora você extraiu a seção para um novo documento.

Método 2: extrair cada seção do documento para novas individuais

Dessa forma, você pode processar em lote todas as seções de um documento. Obviamente, também precisaremos de uma macro.

1. Para começar, abra tarobter documento.
2. Em seguida, siga as etapas do método 1 para instalar e executar uma macro.
3. Só que desta vez substitua essa macro por esta:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Ainda assim, na janela “Browse”, escolha um caminho de armazenamento e clique em “OK”.

Corrigir erros de palavras irritantes

É comum encontrar alguns erros do Word ao usá-lo. Pode ser irritante, devemos ter tempo para recuperar palavra O mais breve possível. Porque quanto mais atrasarmos, mais grave pode ser a perda de dados. Portanto, é recomendável obter um utilitário de reparo com antecedência.

Introdução do autor:

Vera Chen é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo xls corrompidos e pdf reparar produtos de software. Para mais informações visite www.datanumen.com