Hoe u snel alinea's van één zin in uw Word-document kunt vinden

In dit bericht laten we je zien hoe je snel alle alinea's van één zin in je Word-document kunt vinden met behulp van VBA.

Af en toe kunnen sommige documenten zeer specifieke eisen stellen aan hun opmaak en structuur. Het is bijvoorbeeld mogelijk dat u geen alinea's met slechts één zin mag hebben. Deze alinea's zijn niet moeilijk te herkennen, maar het kost tijd, vooral omdat het een lang document is.

Vandaag bieden we u de snelle manier om alle alinea's van één zin in uw document te specificeren.

Vind alle alinea's van één zin in één document

1. Ten eerste telt Word een punt als een zin. Dus als er woorden zijn zoals "Mr." of "Mevrouw", Word beschouwt het als een zin. Om een ​​dergelijke afleiding uit te sluiten, moet u "Mr." vervangen. met "Mr". En als u klaar bent met het vinden van een alinea van een enkele zin, kunt u ze terugzetten. Om woorden te vervangen, kunt u naar deze link verwijzen: Meerdere items in uw Word-document zoeken en vervangen
2. Ten tweede, druk op "Alt + F11" om de VBA-editor te activeren.
3. Klik vervolgens op "Normaal" project.
4. Klik op het tabblad "Invoegen" in de menubalk en kies "Module" in het vervolgkeuzemenu.
5. Dubbelklik vervolgens op de module om deze te openen.
6. Plak de volgende codes op de module:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Last but not least, klik op de knop "Uitvoeren" of druk op "F5".

U ontvangt een dergelijk berichtvenster waarin staat dat de klus is geklaard.

Zoek alle alinea's van één zin in meerdere documenten

1. Om te beginnen moet u alle betreffende documenten in een map plaatsen.
2. Installeer en voer vervolgens de balgmacro uit:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Kies in het geopende venster "Bladeren" de map waarin u de documenten bewaart en klik op "OK".

De macro zal dan alle alinea's van één zin markeren en documenten open laten. Als een document geen alinea van één zin bevat, wordt het gesloten. Bovendien is er een berichtvenster dat het aantal alinea's van één zin in elk document aangeeft.

Omgaan met incidenten met gegevensverlies

Gebruikersfouten en plotselinge stroomuitval kunnen leiden tot de dood van Word. Terwijl een ingestort woord niet alleen het dagelijkse werk kan beïnvloeden, maar ook kan leiden tot doc schadeDit is absoluut niet het meest irritante aspect van een dataverlies. Het is beter om direct een herstelprogramma te gebruiken om de gegevens te herstellen.

Auteur Introductie:

Vera Chen is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder herstel excel en pdf reparatie softwareproducten. Voor meer informatie bezoek www.datanumen.com