Snel de totale tijd die aan de Outlook-afspraken in elke kleurcategorie is besteed, exporteren

Als u een rapport wilt maken over de totale tijd die u aan de afspraken in elke kleurcategorie besteedt, kunt u de methode gebruiken die in dit artikel is geïntroduceerd. Het kan u helpen dit in korte tijd te bereiken zonder handmatig te hoeven tellen.

Veel gebruikers zijn gewend om de meeste van hun activiteiten in de Outlook-agenda vast te leggen. Om deze activiteiten gemakkelijker te beheren en te onderscheiden, wijzen ze er categorieën aan toe. In dat geval willen sommige gebruikers een rapport genereren met de totale tijd die is besteed aan de agendapunten in elke kleurcategorie. Het is natuurlijk omslachtig om dit handmatig te tellen en in te voeren. Daarom delen we hier een manier waarmee u dit met een simpele muisklik kunt doen.

Exporteer de totale tijd besteed aan de afspraken in elke kleurcategorie

1. Start in de eerste plaats uw Outlook-applicatie.
2. Vervolgens kunt u na het openen van het Outlook-venster op de toetsen "Alt + F11" tikken.
3. Vervolgens krijgt u toegang tot het venster “Microsoft Visual Basic for Applications”.
4. Vervolgens moet u de 'Microsoft Excel-objectbibliotheek' inschakelen. U kunt dit doen via 'Extra' > 'Verwijzingen'.
5. Vervolgens moet u een module zoeken en openen die niet in gebruik is.
6. Daarna moet u de volgende VBA-code naar deze module kopiëren.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Eindelijk kunt u deze macro activeren, ongeacht door op het pictogram "Uitvoeren" in de werkbalk te klikken of door op de toets "F5" te drukken.
8. Vervolgens wordt u gevraagd om een ​​specifieke kalender te selecteren.
9. Nadat je hebt geselecteerd en op "OK" hebt geklikt, zal de macro blijven draaien. Nadat het is voltooid, zal er een nieuw Excel-bestand zijn dat op de achtergrond wordt weergegeven.
10. Je hebt er toegang toe. Het ziet er als volgt uit:

Let op mogelijke bedreigingen in uw Outlook

Outlook-gebruikers moeten op alle mogelijke risico's letten, inclusief onbekende e-mailbijlagen, ingesloten links en menselijke fouten. Anders kan uw Outlook op elk moment beschadigd raken. Ook het regelmatig maken van Outlook-gegevensback-ups en het bijhouden van een gespecialiseerde reparatietool is een noodzaak. DataNumen Outlook Repair is een van de meest aanbevolen reparatietools. Het kan reparatie Outlook problemen in een handomdraai.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder beschadigde mdf en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com