Snel de informatie over de grootte van alle mappen in een PST-bestand exporteren naar een Excel-bestand

Als u de informatie over de grootte van elke map in een PST-bestand wilt controleren, kunt u de methode gebruiken die in dit artikel wordt beschreven. Het exporteert snel de informatie over de grootte van alle mappen in een PST-bestand naar een Excel-bestand.

Als uw PST-bestand te groot is, wilt u misschien de grootte van elke map controleren. Het helpt u gemakkelijk erachter te komen welke de grotere zijn en geschikte archivering op basis van de grootte. Om de mapgrootte te controleren, kunt u in het algemeen gewoon met de rechtermuisknop op een map klikken en vervolgens "Eigenschappen" kiezen. In het nieuwe pop-upvenster kunt u op de knop "Mapgrootte" klikken. Als u echter veel mappen heeft aangemaakt, is het een voor een handmatig controleren van de informatie over de grootte aanzienlijk lastig. Dus als u in batch de informatie over de grootte van alle mappen in een PST-bestand wilt krijgen, kunt u de volgende VBA-code gebruiken. Het exporteert alle mapnamen en grootte-informatie in één keer naar een Excel-bestand.

Exporteer de grootte-informatie van alle mappen in een PST-bestand naar een Excel-bestand

1. Begin met het openen van de Outlook-applicatie.
2. Schakel vervolgens over naar het tabblad "Ontwikkelaar" en klik op de knop "Visual Basic" of druk op de toetsen "Alt + F11" om de VBA-editor te openen.
3. Open vervolgens in het venster “Microsoft Visual Basic for Applications” een module die niet in gebruik is.
4. Kopieer en plak vervolgens de volgende VBA-codes in deze module.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Daarna moet u uw Outlook-macrobeveiligingsniveau op laag zetten.
6. Uiteindelijk kun je het proberen.

• Druk op de F5-toets in het huidige macrovenster.
• Vervolgens wordt u gevraagd om een ​​PST-bestand te selecteren, zoals de volgende afbeelding:
• Nadat u een bronbestand heeft geselecteerd, begint Outlook de informatie over de grootte naar Excel te exporteren.
• Nadat de macro is voltooid, ontvangt u een bericht zoals de onderstaande schermafbeelding.
• Ten slotte vindt u het Excel-bestand in de vooraf gedefinieerde lokale map. Het Excel-bestand ziet er als volgt uit:

Omgaan met frequente PST-fouten

Omdat Outlook gevoelig is voor fouten, hebt u mogelijk ooit veel problemen ondervonden in uw Outlook. Om beter en flexibeler met frustrerende PST-problemen om te gaan, is het raadzaam om een ​​ervaren en gerenommeerd reparatieprogramma in de buurt te houden, zoals DataNumen Outlook Repair. Het kan repareer PST problemen als een makkie.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder SQL Server na een training en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com