Snel een Outlook-e-mail exporteren als een afbeeldingsbestand

Sommige gebruikers willen een Outlook-e-mail exporteren als een afbeeldingsbestand, zoals een jpg-bestand. Daarom zullen we u in dit artikel laten zien hoe u het kunt krijgen via Outlook VBA-code.

U moet een aantal trucs hebben geleerd voor het exporteren van een e-mail als tekstbestand, Word-document enzovoort. Hoe zit het dan met het exporteren van een e-mail als afbeelding zoals JPG-bestand? Blijkbaar heeft Outlook deze functie niet. Maar hierna zullen we een snelle manier met u delen.

Exporteer snel een Outlook-e-mail als een afbeeldingsbestand

1. Voor alstart, start uw Outlook-toepassing.
2. Krijg vervolgens in het hoofdvenster van Outlook toegang tot de VBA-editor in overeenstemming met het artikel - "Hoe u VBA-code in uw Outlook uitvoert'.
3. Schakel vervolgens “MS Word Object Library ”en“ MS PowerPoint Objectlibrary "door te verwijzen naar het artikel -"Hoe u een object kunt toevoegen Library Referentie in VBA'.
4. Kopieer en plak vervolgens de volgende VBA-code in een lege module.

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. Daarna moet u de macro toevoegen aan de werkbalk Snelle toegang.
6. Vervolgens kunt u de VBA-editor sluiten.
7. Selecteer later een e-mail en klik op de macroknop in de werkbalk Snelle toegang.
8. Wanneer de macro is voltooid, kunt u naar de vooraf gedefinieerde lokale map gaan om het geëxporteerde afbeeldingsbestand uit deze e-mail te zoeken.

Herstel Outlook-gegevens uit een beschadigd bestand

U kunt behoorlijk frustrerend zijn als uw Outlook-bestand ernstig beschadigd is. In dat scenario gaat u door met het extraheren van Outlook-gegevens uit het gecompromitteerde bestand. Sommige gebruikers zullen de neiging hebben om de reparatietool voor de inbox te gebruiken. Toch most van de tijd zal het geen effecten hebben. Daarom kun je maar beter een formidabel en betrouwbaar houden PST-oplossing tool, zoals DataNumen Outlook Repair​ Het kan het corrupte bestand scannen en maximale gegevens terugkrijgen zonder gedoe.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder mdf-oplossing en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com