Snel een mapstructuur kopiëren van het ene Outlook PST-bestand naar het andere via VBA

Als u de mapstructuur van het ene Outlook PST-bestand naar het andere wilt kopiëren, kunt u de methode gebruiken die in dit artikel is geïntroduceerd, waarin u leert hoe u VBA kunt gebruiken om het in één keer te krijgen.

Misschien hebt u, om uw e-mails beter te beheren, verschillende aangepaste mappen in uw Outlook-hoofdbestand gemaakt. Dus wanneer u een nieuw Outlook PST-bestand maakt, wilt u misschien dezelfde mapstructuur toepassen. Eigenlijk, in mijn vorige artikel - "2 stappen om de huidige mapstructuur te behouden in een nieuw Outlook-bestand”, Kunt u een traditionele methode leren, die de functie" Archief "gebruikt om dit te bereiken. Toch is het eigenlijk nog steeds een beetje vervelend. In vergelijking daarmee zal het gebruik van VBA-codes om het te krijgen veel sneller zijn. Daarom zullen we u in het volgende de uitgebreide stappen en codes vertellen.

Kopieer de mapstructuur van het ene Outlook PST-bestand naar het andere

1. Start allereerst uw Outlook-programma.
2. Druk vervolgens in het Outlook-venster op de toetsen "Alt + F11".
3. Vervolgens komt u in het Outlook VBA-editorvenster.
4. Kopieer en plak vervolgens de volgende VBA-codes in een nieuwe module.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. Wijzig daarna uw macrobeveiligingsniveau naar laag.
6. Later terug naar het VBA-editorvenster en druk op de toets "F5" om de macro uit te voeren.
7. Eindelijk, nadat de macro klaar is met werken, krijgt u een bericht met de vraag "Voltooid!".
8. Op dit punt kunt u naar het e-mailnavigatievenster gaan. U ziet een nieuw Outlook-gegevensbestand dat zich in dezelfde mapstructuur bevindt als het bron-PST-bestand, zoals de afbeelding hieronder:

Omgaan met ontmoedigende PST-problemen

Omdat Outlook PST foutgevoelig is, moeten velen van u ooit verschillende problemen in Outlook hebben ondervonden. Als u hiermee geconfronteerd wordt, kunt u eerst de Outlook-inbox-reparatietool gebruiken om het te proberen. Als het niet lukt, kunt u een krachtigere tool van derden toepassen, zoals DataNumen Outlook Repair, welke kan Outlook repareren PST-fouten als een eitje.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder SQL Server repareren en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com