Hoe u snel de specifieke pagina's van een Word-document aan een Outlook-e-mail kunt koppelen

Outlook-oplossingen 29 september 2025

MS Word heeft een directe functie die gebruikers ondersteunt om het huidige Word-document als e-mailbijlage te verzenden. Maar soms hoopt u misschien alleen de specifieke pagina's van een Word-document bij een Outlook-e-mail te voegen. Dit artikel zal u nu een methode delen.

Om een ​​volledig Word-document als e-mailbijlage in de MS Word-toepassing te verzenden, gaat u eenvoudig naar het menu "Bestand" en gaat u naar het tabblad "Opslaan en verzenden", waar u een knop "Verzenden als bijlage" kunt vinden. Maar soms zijn wat u wilt verzenden alleen specifieke pagina's van het document. In deze situatie kunt u de methode gebruiken die in het volgende wordt geïntroduceerd om dit te bereiken.

Voeg snel de specifieke pagina's van een Word-document toe aan een Outlook-e-mail

Voeg de specifieke pagina's van een Word-document toe aan een e-mail

  1. Allereerst moet u het bron-Word-document openen waarvan u de specifieke pagina's in e-mail wilt verzenden.
  2. Vervolgens moet u, nadat u in het MS Word-venster bent gekomen, op de toetsen "Alt + F11" drukken.
  3. Vervolgens krijgt u toegang tot de VBA-editor in MS Word.
  4. Daarna moet u de 'Microsoft Outlook-objectbibliotheek' inschakelen. U kunt dit doen via 'Extra' > 'Referenties'.
  5. Vervolgens moet u de volgende VBA-code kopiëren naar een module die niet in gebruik is.
Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

VBA-code - Voeg de specifieke pagina's van een Word-document toe aan een e-mail

  1. Eindelijk kunt u deze macro uitvoeren. Druk gewoon op de F5-toets of tik op het pictogram "Uitvoeren" in de werkbalk.
  2. Nadat de macro is voltooid, wordt een nieuwe Outlook-e-mail weergegeven, die is bijgevoegd met een uittreksel van het bron-Word-document, zoals de volgende schermafbeelding:nieuwe e-mail

Extraheer maximale gegevens uit beschadigd Outlook-bestand

Als u Outlook al tientallen jaren gebruikt, bent u mogelijk geconfronteerd met verschillende Outlook-problemen, waaronder pop-up-foutmeldingen, plotselinge crashes en ernstige bestandsbeschadiging. Vanwege het feit dat de scanpst, ingebouwde reparatietool, kan alleen de kleine problemen oplossen, u kunt bijvoorbeeld maar beter een externe krachtige reparatietool bij de hand houden DataNumen Outlook Repair. Het is in staat om maximale gegevens uit het beschadigde Outlook-gegevensbestand te halen.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder sql-oplossing en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com

Reacties zijn gesloten.