Hoe u verschillende standaardherinneringstijden kunt instellen voor verschillende soorten gemarkeerde items in uw Outlook

Standaard gebruikt Outlook automatisch de standaard herinneringstijd van taken voor allerlei gemarkeerde items. Als u echter een andere herinneringstijd wilt gebruiken voor gemarkeerde items op basis van het itemtype, kunt u de methode raadplegen die in dit artikel is geïntroduceerd.

Met Outlook kunt u de standaardherinneringstijd instellen voor alle gemarkeerde items, ongeacht het itemtype. U kunt naar het menu "Bestand" gaan en op "Opties" klikken. Vervolgens ziet u in het venster "Outlook-opties" de optie "Standaard herinneringstijd" op het tabblad "Taken", zoals weergegeven in de volgende schermafbeelding.

De meeste gebruikers willen echter verschillende herinneringstijden gebruiken voor verschillende soorten gemarkeerde items, bijvoorbeeld "9:00" voor gemarkeerde e-mails en "17:30" voor gemarkeerde contactpersonen. In het volgende zullen we ons richten op dit voorbeeld om een ​​methode te introduceren.

Stel verschillende standaardherinneringstijden in voor verschillende soorten gemarkeerde items

1. Begin met het opstarten van de Outlook-applicatie.
2. Open vervolgens de Outlook VBA-editor met verwijzing naar "Hoe u VBA-code in uw Outlook uitvoert'.
3. Kopieer in het daaropvolgende venster "Microsoft Visual Basic for Applications" de volgende code naar het project "ThisOutlookSession".

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Start Outlook daarna opnieuw op om deze macro te activeren.
5. Vanaf nu wordt elke keer dat u een e-mail markeert, de herinneringstijd ingesteld op "10:00" op de vervaldatum van de vlag.
6. En wanneer u een contactpersoon markeert, wordt de herinneringstijd ingesteld op "17:30" op de vervaldatum van de vlag.

Pak Outlook-problemen flexibel aan

Je kunt allerlei problemen tegenkomen in Outlook. Daarom is het belangrijk om van tevoren te weten hoe je hiermee om moet gaan. Als Outlook bijvoorbeeld vaak opnieuw opstart, moet je Office repareren of invoegingen van derden uitschakelen, enzovoort. Of als je Outlook PST-bestand is gecompromitteerd, kun je eerst proberen... inbox reparatieprogramma. Als het niet lukt, kunt u doorgaan met het gebruiken van een krachtige externe tool, zoals DataNumen Outlook Repair.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder mdf herstel en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com