Snel alle ontvangers extraheren uit meerdere Outlook-berichtbestanden (.msg)

Sommige gebruikers willen snel alle ontvangers extraheren uit meerdere Outlook-berichtbestanden die zijn opgeslagen vanuit Outlook-e-mails. Nu, deze post zal dit bekijken om een ​​snelle aanpak te delen.

Om de ontvangers uit een enkel Outlook-berichtbestand te extraheren, dubbelklikt u erop om het te openen en kopieert u de ontvangers in het geopende berichtvenster. Maar als u te maken heeft met een batch Outlook-berichtbestanden, is de handmatige methode niet efficiënt genoeg. U kunt dus op zoek gaan naar een veel efficiëntere manier. Hier zullen we zo iemand aan u voorstellen. Lees verder voor de details.

Pak alle ontvangers uit uit meerdere Outlook-berichtbestanden (.msg)

1. Voor alstart, krijg toegang tot de Outlook VBA-editor volgens “Hoe u VBA-code in uw Outlook uitvoert'.
2. Kopieer en plak vervolgens de volgende VBA-code in een lege module.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Verplaats vervolgens de cursor in de eerste subroutine.
4. Klik vervolgens op de knop "Uitvoeren" of druk op de toets "F5".
5. Selecteer vervolgens in het pop-upvenster de Windows-map die de Outlook-bronberichtbestanden (.msg) bevat.
6. Klik na het selecteren op "OK" om de macro te laten doorgaan.
7. Wanneer de macro is voltooid, verschijnt er een bericht met een lijst van alle geëxtraheerde e-mailadressen van ontvangers, zoals weergegeven in de volgende schermafbeelding.

Bescherm uw Outlook-gegevens tegen gevaar

Outlook-gegevens zijn weliswaar vatbaar voor corruptie. Daarom is het een vrij zware taak om Outlook-gegevens te beschermen. Het vereist dat u volhardt bij het maken van regelmatige back-ups van Outlook-gegevens. Ook is het, indien mogelijk, verstandig en aanbevolen om een ​​ervaren en professionele Outlook voor te bereiden PST-reparatie tool, zoals DataNumen Outlook Repair, zodat u onmiddellijk en tijdig redding kunt krijgen in het geval van Outlook-corruptie.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder herstellen Sql Server en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com