Snel een contactgroep maken van alle Outlook-contactpersonen met een specifieke functietitel

Om makkelijker te communiceren met de contacten met een specifieke functietitel, wil je misschien snel een contactgroep aanmaken van deze contacten. In dit artikel zullen we een snelle methode met je delen.

Als u regelmatig e-mails, taken of uitnodigingen voor vergaderingen verzendt naar de contacten met een specifieke functietitel, is het veel handiger als u van hen een contactgroep maakt. Over het algemeen moet u op de standaardmanier eerst een nieuwe contactgroep maken en vervolgens contacten één voor één aan de groep toevoegen als leden. Het is een beetje lastig. Daarom leren we je in het volgende een veel snellere manier om het te krijgen.

Maak een contactgroep van alle contacten met een specifieke functietitel

1. Selecteer eerst in een map Contacten een contactpersoon met de specifieke functietitel.
2. Druk vervolgens op "Alt + F11" om toegang te krijgen tot de Outlook VBA-editor.
3. Kopieer vervolgens de volgende VBA-code naar een lege module of project.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. Verplaats daarna de cursor naar de eerste subroutine.
5. Tik ten slotte op de toets "F5" om deze macro uit te voeren.
6. Wanneer de macro is voltooid, wordt een nieuwe contactgroep weergegeven. Het bevat alle contacten met dezelfde functietitel als het geselecteerde contact in stap 1.

Bescherm Outlook-gegevens effectief

Hoewel Outlook rijk is aan functies, kan het niet verlossen van het feit dat het kwetsbaar is. Dus als u uw kostbare Outlook-gegevens niet wilt verliezen, moet u zich inspannen om deze te beschermen. U moet bijvoorbeeld regelmatig back-ups maken van Outlook-gegevens. Als het betaalbaar is, wordt het ook aanbevolen om een ​​geavanceerde PST-reparatietool te hebben, zoals DataNumen Outlook Repair, welke kan reparatie PST gegevens in een handomdraai.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder beschadigde sql en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com